File Coverage

blib/lib/Config/PL.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	17	18	94.4
condition	3	3	100.0
subroutine	9	9	100.0
pod	1	1	100.0
total	74	75	98.6

package Config::PL;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.03";

use Carp ();
use Cwd ();
use File::Basename ();

our @EXPORT = qw/config_do/;
our %CONFIG;

sub import {
    my ($pkg, @args) = @_;
    my $caller = caller;

    my @export;
    if (@args) {
        push @export, shift(@args) while $args[0] && $args[0] !~ '^:';
        my %conf = @args;
        $CONFIG{path} = $conf{':path'} if exists $conf{':path'};
    }
    @export = @EXPORT unless @export;

    for my $func (@export) {
        Carp::croak "'$func' is not exportable function" unless grep {$_ eq $func} @EXPORT;

        no strict 'refs';
        *{"$caller\::$func"} = \&$func;
    }
}

sub config_do($) {
    my $config_file = shift;
    my (undef, $file,) = caller;

    my ($config, $errno) = do {
        local @INC = (Cwd::getcwd, File::Basename::dirname($file));
        push @INC, $CONFIG{path} if defined $CONFIG{path};

        (scalar do $config_file, $!);
    };

    Carp::croak $@ if $@;
    Carp::croak $errno unless defined $config;
    unless (ref $config eq 'HASH') {
        Carp::croak "$config_file does not return HashRef.";
    }

    wantarray ? %$config : $config;
}

1;
__END__