File Coverage

blib/lib/Config/Maker/Config.pm

Criterion	Covered	Total	%
statement	54	56	96.4
branch	5	8	62.5
condition	2	3	66.6
subroutine	13	14	92.8
pod	0	4	0.0
total	74	85	87.0

package Config::Maker::Config;

use utf8;
use warnings;
use strict;

use Carp;
use Parse::RecDescent;

use Config::Maker;
use Config::Maker::Encode;
use Config::Maker::Option;
use Config::Maker::Option::Meta;
use Config::Maker::Type;

our $parser = $Config::Maker::parser;

# Now to the parser itself...

sub new {
    my ($class, $root) = @_;

    unless(UNIVERSAL::isa($root, 'Config::Maker::Option')) {
	# We didn't get a Config::Maker::Option, so let's assume we've got
	# a filename
	my $type = Config::Maker::Type->root;

	my $children = $class->read($root, $type);

	$root = $type->instantiate({ -children => $children });
    }

    bless {
	root => $root,
	meta => Config::Maker::Option::Meta->new(
		    -type => Config::Maker::Type->meta()
		),
    }, $class;
}

sub read {
    my ($class, $file, $type) = @_;
    my ($fh, $text);
    my $enc = 'system';

    $file = Config::Maker::locate($file);

    open($fh, '<', $file)
	or croak "Failed to open $file: $!";
    {
	local $/;
	$text = <$fh>;
    }
    close $fh;

    if((substr($text, 0, 250) =~ /^\s*#.*$Config::Maker::fenc([[:alnum:]_-]+)/m) ||
       (substr($text, -250)   =~ /^\s*#.*$Config::Maker::fenc([[:alnum:]_-]+)/m)) {
       $enc = $1;
    }
    $text = decode($enc, $text);

    LOG("Loading configuration from $file using encoding $enc");
    my $options = $parser->configuration($text, undef, $type);
    croak "Configuration file $file contained errors"
	unless defined $options;

    return $options;
}

sub meta {
    my ($self, $name) = @_;
    $self->{meta}->get($name);
}

sub set_meta {
    my ($self, $name, $value) = @_;
    $self->{meta}->set_child($name, $value);
}

1;

__END__