File Coverage

blib/lib/Config/BuildHelper.pm

Criterion	Covered	Total	%
statement	56	59	94.9
branch	7	10	70.0
condition			n/a
subroutine	13	13	100.0
pod	1	1	100.0
total	77	83	92.7

package Config::BuildHelper;

our $VERSION = '0.02';

use base qw(Data::Classifier);

use strict;
use warnings;

use Data::Dumper;

sub return_result {
	my ($self, $ret) = @_;

	return Config::BuildHelper::Result->new($ret);
}

package Config::BuildHelper::Result;

use strict;
use warnings;

use base qw(Data::Classifier::Result);

use Data::Dumper;

sub config_list {
	my ($self) = @_;

	if (defined($self->{QUERY_HASH})) {
		return(keys(%{$self->{QUERY_HASH}}));
	}

	$self->{QUERY_HASH} = {};

	foreach my $one ($self->attributes('data')) {
		my $node_query = $one->{config};

		if (ref($node_query) eq 'ARRAY') {
			foreach my $one_query (@$node_query) {
				#copy this to a local variable so when
				#we shift off of it, it does not effect
				#everyone else
				my @query_list = @$one_query;
				my $op = shift(@query_list);

				if ($op eq 'ADD') {
					$self->config_add(@query_list);
				} elsif ($op eq 'REMOVE') {
					$self->config_remove(@query_list);
				} elsif ($op eq 'SET') {
					$self->config_set(@query_list);
				} else {
					die "unknown OP: $op";
				}
			}
		}
	}

	return keys(%{$self->{QUERY_HASH}});
}

sub config_add {
	my $self = shift(@_);
	my $query_hash = $self->{QUERY_HASH};
	my @queries = @_;

	foreach my $one (@queries) {
		$query_hash->{$one} = 1;
	}

	return 1;
}

sub config_remove {
	my $self = shift(@_);
	my $query_hash = $self->{QUERY_HASH};
	my @queries = @_;

	foreach my $one (@queries) {
		delete($query_hash->{$one});
	}

	return 1;
}

sub config_set {
	my $self = shift;
	my $query_hash = $self->{QUERY_HASH} = {};

	return $self->config_add(@_);
}

1;

__END__