File Coverage

blib/lib/Color/Theme/Util.pm

Criterion	Covered	Total	%
statement	28	53	52.8
branch	6	20	30.0
condition	1	10	10.0
subroutine	6	7	85.7
pod	2	2	100.0
total	43	92	46.7

package Color::Theme::Util;

our $DATE = '2018-02-25'; # DATE
our $VERSION = '0.020'; # VERSION

use 5.010001;
use strict;
use warnings;

require Exporter;
our @ISA       = qw(Exporter);
our @EXPORT_OK = qw(
                       create_color_theme_transform
                       get_color_theme
               );

sub create_color_theme_transform {
    my ($basect, $func) = @_;

    my $derivedct = {};

    for my $cn (keys %{ $basect->{colors} }) {
        my $cv = $basect->{colors}{$cn};

        if ($cv) {
            $derivedct->{colors}{$cn} = sub {
                my ($self, %args) = @_;
                my $basec = $basect->{colors}{$cn};
                if (ref($basec) eq 'CODE') {
                    $basec = $basec->($self, name=>$cn, %args);
                }
                if ($basec) {
                    if (ref($basec) eq 'ARRAY') {
                        $basec = [map {defined($_) && /^#?[0-9A-Fa-f]{6}$/ ?
                                           $func->($_) : $_} @$basec];
                    } else {
                        for ($basec) {
                            $_ = defined($_) && /^#?[0-9A-Fa-f]{6}$/ ?
                                $func->($_) : $_;
                        }
                    }
                }
                return $basec;
            };
        } else {
            #$derivedct->{colors}{$cn} = $cv;
        }
    }
    $derivedct;
}

sub get_color_theme {
    no strict 'refs';

    my $opts  = ref($_[0]) eq 'HASH' ? shift : {};
    my $name0 = shift;

    my $modprefixes    = $opts->{module_prefixes} // ["Generic::ColorTheme"];
    my $themeprefixes0 = $opts->{theme_prefixes}  // ["Default"];

    my (@themeprefixes, $name);
    if ($name0 =~ /(.+)::(.+)/) {
        @themeprefixes = ($1);
        $name = $2;
    } else {
        @themeprefixes = @$themeprefixes0;
        $name = $name0;
    }

    my @searched_mods;
    for my $modprefix (@$modprefixes) {
        for my $themeprefix (@themeprefixes) {
            my $mod = "$modprefix\::$themeprefix";
            push @searched_mods, $mod;
            (my $mod_pm = "$mod.pm") =~ s!::!/!g;
            if (eval { require $mod_pm; 1 }) {
                my $color_themes = \%{"$mod\::color_themes"};
                return $color_themes->{$name} if $color_themes->{$name};
            }
        }
    }
    die "Can't find color theme '$name0' (searched in ".
        join(", ", @searched_mods).")";
}

1;
# ABSTRACT: Utility routines related to color themes

__END__