File Coverage

blib/lib/Code/TidyAll/Plugin/Perl/IgnoreMethodSignaturesSimple.pm

Criterion	Covered	Total	%
statement	9	31	29.0
branch	0	2	0.0
condition			n/a
subroutine	3	7	42.8
pod	2	2	100.0
total	14	42	33.3

package Code::TidyAll::Plugin::Perl::IgnoreMethodSignaturesSimple;
$Code::TidyAll::Plugin::Perl::IgnoreMethodSignaturesSimple::VERSION = '0.03';
use strict;
use warnings;
use base qw(Code::TidyAll::Plugin);

sub preprocess_source {
    my ( $self, $source ) = @_;

    $source =~
      s/^\h*(method|func)\s+(\w+)([^\{]+)\{/$self->_munged_sub($1, $2, $3)/gme;

    return $source;
}

sub postprocess_source {
    my ( $self, $source ) = @_;

    foreach my $id ( keys( %{ $self->{saves} } ) ) {
        my ( $keyword, $name, $rest ) = @{ $self->{saves}->{$id} };
        for ( $name, $rest ) { s/^\s+//; s/\s+$// }

        # Blank parens if no params list
        #
        $rest = '()' if $rest !~ /\S/;

        # No space inside parens
        #
        $rest =~ s/\(\s+/\(/;
        $rest =~ s/\s+\)/\)/;

        $source =~ s/sub MUNGED_${id}_/$keyword $name $rest/;
    }

    return $source;
}

sub _munged_sub {
    my ( $self, $keyword, $name, $rest ) = @_;

    my $id = $self->_unique_id;
    $self->{saves}->{$id} = [ $keyword, $name, $rest ];
    return "sub MUNGED_${id}_ {";
}

my $unique_id = 0;

sub _unique_id {
    return join( '_', time, $unique_id++ );
}

1;

__END__