File Coverage

blib/lib/Closure/Loop.pm

Criterion	Covered	Total	%
statement	44	44	100.0
branch	10	14	71.4
condition	6	12	50.0
subroutine	9	9	100.0
pod	1	1	100.0
total	70	80	87.5

package Closure::Loop;

use warnings;
use strict;
use Carp;

use version; our $VERSION = qv('0.0.3');

my @SIGS    = qw(last next redo);
my @EXPORTS = qw(yield);

sub import {
    my $caller  = caller;
    my %signals = map { $_ => 1 } ( @SIGS, @_ );

    no strict 'refs';

    for my $sig (keys %signals) {
        *{ $caller . '::' . $sig } = sub {
            my $self = shift;
            croak "$sig must be called as a method"
                unless ref($self) && $self->isa($caller);
            die [ $self, $sig ];
        };

        *{ $caller . '::is_' . $sig } = sub {
            my $self  = shift;
            croak "is_$sig must be called as a method"
                unless ref($self) && $self->isa($caller);
            my $excep = shift || $@;
            return ref($excep) eq 'ARRAY' &&
                   $excep->[0] == $self &&
                   $excep->[1] eq $sig;
        };
    }

    for my $sub ( @EXPORTS ) {
        *{ $caller . '::' . $sub } = \&{ $sub };
    }
}

sub yield {
    my $self = shift;
    my $cb   = shift;

    croak "yield must be called as a method"
        unless ref($self);

    croak "yield must be called with a callback (code ref)"
        unless ref($cb) eq 'CODE';

    Y: {
        eval {
            $cb->(@_);
        };
        redo Y if $self->is_redo;
        return if $self->is_next;
        die $@ if $@;
    }
}

1;
__END__