File Coverage

blib/lib/Class/Scaffold/Introspect.pm

Criterion	Covered	Total	%
statement	41	48	85.4
branch	5	12	41.6
condition	2	9	22.2
subroutine	11	11	100.0
pod	2	2	100.0
total	61	82	74.3

use 5.008;
use warnings;
use strict;

package Class::Scaffold::Introspect;
BEGIN {
  $Class::Scaffold::Introspect::VERSION = '1.102280';
}
# ABSTRACT: Find configuration files within the framework
use FindBin '$Bin';
use Cwd;
use File::Spec::Functions qw/curdir updir rootdir rel2abs/;
use Sys::Hostname;
use Exporter qw(import);
our %EXPORT_TAGS = (conf => [qw/find_conf_file/],);
our @EXPORT_OK = @{ $EXPORT_TAGS{all} = [ map { @$_ } values %EXPORT_TAGS ] };

sub find_file_upwards {
    my $wanted_file  = shift;
    my $previous_cwd = getcwd;
    my $result;    # left undef as we'll return undef if we didn't find it
    while (rel2abs(curdir()) ne rootdir()) {
        if (-f $wanted_file) {
            $result = rel2abs(curdir());
            last;
        }
        chdir(updir());
    }
    chdir($previous_cwd);
    $result;
}

sub find_conf_file {
    my $file = 'SMOKEconf.yaml';

    # the distribution root is where Build.PL is; start the search from where
    # the bin file was (presumably within the distro). This way we can say any
    # of:
    #
    # perl t/sometest.t
    # cd t; perl sometest.t
    # perl /abs/path/to/distro/t/sometest.t
    chdir($Bin) or die "can't chdir to [$Bin]: $!\n";
    my $distro_root = find_file_upwards('Makefile.PL')
        || find_file_upwards('dist.ini');
    unless (defined $distro_root && length $distro_root) {
        warn "can't find distro root from [$Bin]\n";
        warn "might not be able to find conf file using [$ENV{CF_CONF}]\n"
          if $ENV{CF_CONF} eq 'local';
        return;
    }
    my $etc = "$distro_root/etc";
    return "$etc/$file" if -e "$etc/$file";

    # warn "find_conf_file: not in [$etc/$file]";
    (my $hostname = hostname) =~ s/\W.*//;
    my $dir = "$etc/$hostname";
    return "$dir/$file" if -d $dir && -e "$dir/$file";

    # warn "find_conf_file: not in [$dir/$file]";
    undef;
}
1;


__END__