File Coverage

blib/lib/Class/Data/Localize.pm

Criterion	Covered	Total	%
statement	28	29	96.5
branch	9	10	90.0
condition	5	6	83.3
subroutine	6	6	100.0
pod	1	1	100.0
total	49	52	94.2

package Class::Data::Localize;

use strict qw(vars subs);
use vars qw($VERSION);
$VERSION = '0.0401';

use ReleaseAction ();

sub mk_classdata {
    my ($declaredclass, $attribute, $data) = @_;

    if( ref $declaredclass ) {
        require Carp;
        Carp::croak("mk_classdata() is a class method, not an object method");
    }

    my $accessor = sub {
        my $wantclass = ref($_[0]) || $_[0];

        if(@_==3) {
            my $current = $data;
            $_[2] = ReleaseAction->new( sub { $data = $current } );

            if($wantclass ne $declaredclass){
                return mk_classdata($wantclass,$attribute,$data)->(@_);
            }
        }
        else {
            return mk_classdata($wantclass,$attribute)->(@_)
              if @_>1 && $wantclass ne $declaredclass;
        }
        $data = $_[1] if @_>1;
        return $data;
    };

    my $alias = "_${attribute}_accessor";
    *{$declaredclass.'::'.$attribute} = $accessor;
    *{$declaredclass.'::'.$alias}     = $accessor;
}

1;

__END__