File Coverage

blib/lib/Class/DBI/Sweet/Topping.pm

Criterion	Covered	Total	%
statement	23	24	95.8
branch	4	8	50.0
condition	3	8	37.5
subroutine	3	3	100.0
pod			n/a
total	33	43	76.7

package Class::DBI::Sweet::Topping;

use strict;
use Class::DBI::Sweet;

# Alias
*Class::DBI::Sweet::find = \&Class::DBI::Sweet::search;

sub Class::DBI::Sweet::AUTOLOAD {
    my $self = shift;
    our $AUTOLOAD = $Class::DBI::Sweet::AUTOLOAD;
    my $super_meth = $AUTOLOAD;
    $super_meth =~ s/(?:.*::)?/SUPER::/;
    $AUTOLOAD =~ m/(search|find|page|count|(?:previous|next)_by)_(.*)/
        || return $self->$super_meth(@_);
    my $method = $1 || '';
    my $query = $2 || '';
    return 0 unless $query;
    my @keys = split /_and_/, $query;
    my %con;

    for my $key (@keys) {
        if ($method =~ /_by/) {
            $con{$key} = $self->$key; # previous/next_by conds are from self
        } else {
            $con{$key} = shift || '';
        }
    }

    $method =~ s/(.*)_by/retrieve_$1/; # Convert next_by to retrieve_next

    my $attrs = shift || {};

    return wantarray()
        ? @{[$self->$method( \%con, $attrs )]}
        : $self->$method( \%con, $attrs );
}

1;

__END__