File Coverage

blib/lib/Cisco/SNMP/Interface.pm

Criterion	Covered	Total	%
statement	18	368	4.8
branch	0	174	0.0
condition	0	33	0.0
subroutine	8	23	34.7
pod	13	13	100.0
total	39	611	6.3

package Cisco::SNMP::Interface;

##################################################
# AUTHOR = Michael Vincent
# www.VinsWorld.com
##################################################

use strict;
use warnings;

use Net::SNMP qw(:asn1);
use Cisco::SNMP;

our $VERSION = $Cisco::SNMP::VERSION;

our @ISA = qw(Cisco::SNMP);

##################################################
# Start Public Module
##################################################

sub _ifOID {
    return '1.3.6.1.2.1.2.2.1'
}

sub ifOIDs {
    return qw(Index Description Type MTU Speed PhysAddress AdminStatus OperStatus LastChange Duplex Name Alias)
}

sub ipOIDs {
    return qw(Addr NetMask)
}

sub ifMetricUserOIDs {
    return qw(Multicasts Broadcasts Octets Unicasts Discards Errors Unknowns)
}

sub ifMetricOIDs {
    return qw(InMulticasts OutMulticasts InBroadcasts OutBroadcasts InOctets OutOctets InUnicasts OutUnicasts InDiscards OutDiscards InErrors OutErrors InUnknowns)
}

sub _ifMetricOIDVals {
    return qw(InOctets 10 OutOctets 16 InUnicasts 11 OutUnicasts 17 InDiscards 13 OutDiscards 19 InErrors 14 OutErrors 20 InUnknowns 15)
}

sub interface_getbyindex {
    my $self = shift;

    my $session = $self->{_SESSION_};

    my $uIfx;
    my %args;
    if (@_ == 1) {
        ($uIfx) = @_;
        if ($uIfx !~ /^\d+$/) {
            $Cisco::SNMP::LASTERROR = "Invalid ifIndex `$uIfx'";
            return undef
        }
    } else {
        %args = @_;
        for (keys(%args)) {
            if ((/^-?interface$/i) || (/^-?index$/i)) {
                if ($args{$_} =~ /^\d+$/) {
                    $uIfx = $args{$_}
                } else {
                    $Cisco::SNMP::LASTERROR = "Invalid ifIndex `$args{$_}'";
                    return undef
                }
            }
        }
    }
    if (!defined $uIfx) {
        $Cisco::SNMP::LASTERROR = "No ifIndex provided";
        return undef
    }
    my $rIf  = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.2');
    if (!defined $rIf) {
        $Cisco::SNMP::LASTERROR = "Cannot get interface names from device";
        return undef
    }
    my $rIfx = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.1');

    for (0..$#{$rIfx}) {
        if ($rIfx->[$_] == $uIfx) {
            return $rIf->[$_]
        }
    }
    $Cisco::SNMP::LASTERROR = "Cannot get interface for ifIndex `$uIfx'";
    return undef
}

sub interface_getbyname {
    my $self = shift;

    my $session = $self->{_SESSION_};

    my %params = (
        'index' => 0
    );

    my %args;
    if (@_ == 1) {
        ($params{uIf}) = @_
    } else {
        %args = @_;
        for (keys(%args)) {
            if (/^-?interface$/i) {
                $params{uIf} = $args{$_}
            } elsif (/^-?index$/i) {
                if ($args{$_} == 1) {
                    $params{index} = 1
                }
            }
        }
    }
    if (!exists($params{uIf})) {
        $Cisco::SNMP::LASTERROR = "No interface provided";
        return undef
    }

    my $rIf  = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.2');
    if (!defined $rIf) {
        $Cisco::SNMP::LASTERROR = "Cannot get interface names from device";
        return undef
    }
    my $rIfx = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.1');

    # user Provided
    # split Gig0/1 into 'Gig' '0/1'
    my @parts = split /([0-9])/, $params{uIf}, 2;
    my $uIfNamePart =  shift @parts;
    my $uIfNumPart  =  "@parts";
       $uIfNumPart  =~ s/\s+//;

    my @matches;
    my $idx;
    for (0..$#{$rIf}) {
        # Real Names
        @parts = split /([0-9])/, $rIf->[$_], 2;
        my $rIfNamePart =  shift @parts;
        my $rIfNumPart  =  "@parts";
           $rIfNumPart  =~ s/\s+//;
        if (($rIfNamePart =~ /^$uIfNamePart/i) && ($rIfNumPart eq $uIfNumPart)) {
            push @matches, $rIf->[$_];
            $idx = $rIfx->[$_]
        }
    }
    if (@matches == 1) {
        if ($params{index} == 0) {
            return "@matches"
        } else {
            return $idx
        }
    } elsif (@matches == 0) {
        $Cisco::SNMP::LASTERROR = "Cannot find interface `$params{uIf}'";
        return undef
    } else {
        print "Interface `$params{uIf}' not specific enough - [@matches]";
        return undef
    }
}

sub interface_info {
    my $self  = shift;
    my $class = ref($self) || $self;

    my $session = $self->{_SESSION_};

    my %params = (
        'ifs' => [-1]
    );

    my %args;
    if (@_ == 1) {
        ($params{ifs}) = @_;
        if (!defined($params{ifs} = Cisco::SNMP::_get_range($params{ifs}))) {
            return undef
        }
    } else {
        %args = @_;
        for (keys(%args)) {
            if (/^-?interface(?:s)?$/i) {
                if (!defined($params{ifs} = Cisco::SNMP::_get_range($args{$_}))) {
                    return undef
                }
            }
        }
    }

    my %IfInfo;
    for my $ifs (@{$params{ifs}}) {

        my $interface;
        if ($ifs == -1) {
            $interface = ''
        } else {
            $interface = '.' . $ifs
        }

        my %ret;
        my @IFKEYS = ifOIDs();
        # -3 because last key (Duplex Name Alias) are different OID
        for my $oid (0..$#IFKEYS-3) {
            $ret{$IFKEYS[$oid]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.' . ($oid+1) . $interface);
            if (!defined $ret{$IFKEYS[$oid]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFKEYS[$oid]'";
                return undef
            }
        }
        # Name Alias are different OID
        $ret{Name} = Cisco::SNMP::_snmpwalk($session, '.1.3.6.1.2.1.31.1.1.1.1' . $interface);
        $ret{Alias} = Cisco::SNMP::_snmpwalk($session, '.1.3.6.1.2.1.31.1.1.1.18' . $interface);
        # Duplex is different OID
        my $OIDS;
        ($OIDS, $ret{$IFKEYS[9]}) = Cisco::SNMP::_snmpwalk($session, '1.3.6.1.2.1.10.7.2.1.19' . $interface);
        my %duplexIfs;
        for (0..$#{$OIDS}) {
            # split the OID at dots
            my @if = split /\./, $OIDS->[$_];
            # take the last value, which is the ifIndex equal to value returned
            $duplexIfs{$if[$#if]} = $ret{$IFKEYS[9]}->[$_]
        }

        my %UpDownStatus = (
            1 => 'UP',
            2 => 'DOWN',
            3 => 'TEST',
            4 => 'UNKNOWN',
            5 => 'DORMANT',
            6 => 'NOTPRESENT',
            7 => 'LOWLAYERDOWN'
        );
        my %DuplexType = (
            1 => 'UNKNOWN',
            2 => 'HALF',
            3 => 'FULL'
        );
        for my $idx (0..$#{$ret{$IFKEYS[0]}}) {
            my %IfInfoHash;
            for (0..$#IFKEYS) {
                if ($_ == 5) {
                    $IfInfoHash{$IFKEYS[$_]} = ($ret{$IFKEYS[$_]}->[$idx] =~ /^\0/) ? unpack('H12', $ret{$IFKEYS[$_]}->[$idx]) : (($ret{$IFKEYS[$_]}->[$idx] =~ /^0x/) ? substr($ret{$IFKEYS[$_]}->[$idx],2) : $ret{$IFKEYS[$_]}->[$idx])
                } elsif (($_ == 6) || ($_ == 7)) {
                    $IfInfoHash{$IFKEYS[$_]} = exists($UpDownStatus{$ret{$IFKEYS[$_]}->[$idx]}) ? $UpDownStatus{$ret{$IFKEYS[$_]}->[$idx]} : $ret{$IFKEYS[$_]}->[$idx]
                } elsif ($_ == 9) {
                    # if $duplexIfs{ifIndex}, not necessarily the current array index
                    if (exists $duplexIfs{$ret{$IFKEYS[0]}->[$idx]}) {
                        $IfInfoHash{$IFKEYS[$_]} = exists($DuplexType{$duplexIfs{$ret{$IFKEYS[0]}->[$idx]}}) ? $DuplexType{$duplexIfs{$ret{$IFKEYS[0]}->[$idx]}} : $duplexIfs{$ret{$IFKEYS[0]}->[$idx]}
                    } else {
                        $IfInfoHash{$IFKEYS[$_]} = ''
                    }
                } else {
                    $IfInfoHash{$IFKEYS[$_]} = $ret{$IFKEYS[$_]}->[$idx]
                }
            }
            $IfInfo{$ret{$IFKEYS[0]}->[$idx]} = \%IfInfoHash
        }
    }
    return bless \%IfInfo, $class
}

for (ifOIDs()) {
    Cisco::SNMP::_mk_accessors_hash_1('if', $_)
}

sub interface_metrics {
    my $self  = shift;
    my $class = ref($self) || $self;

    my $session = $self->{_SESSION_};

    my %params = (
        'ifs' => [-1],
    );
    # assume all metrics
    my @IFMETRICUSERKEYS = ifMetricUserOIDs();
    for (@IFMETRICUSERKEYS) {
        $params{$_} = 1
    }

    my %args;
    if (@_ == 1) {
        ($params{ifs}) = @_;
        if (!defined($params{ifs} = Cisco::SNMP::_get_range($params{ifs}))) {
            return undef
        }
    } else {
        %args = @_;
        for (keys(%args)) {
            if (/^-?interface(?:s)?$/i) {
                if (!defined($params{ifs} = Cisco::SNMP::_get_range($args{$_}))) {
                    return undef
                }
            } elsif (/^-?metric(?:s)?$/i) {
                # metrics provided - only use provided
                for (@IFMETRICUSERKEYS) {
                    $params{$_} = 0
                }
                if (ref($args{$_}) eq 'ARRAY') {
                    $params{oids} = '';
                    for my $mets (@{$args{$_}}) {
                        if (exists($params{ucfirst(lc($mets))})) {
                            $params{ucfirst(lc($mets))} = 1
                        } else {
                            $Cisco::SNMP::LASTERROR = "Invalid metric `$mets'";
                            return undef
                        }
                    }
                } else {
                    $params{oids} = '';
                    if (exists($params{ucfirst(lc($args{$_}))})) {
                        $params{ucfirst(lc($args{$_}))} = 1
                    } else {
                        $Cisco::SNMP::LASTERROR = "Invalid metric `$args{$_}'";
                        return undef
                    }
                }
            }
        }
    }

    my %IfMetric;
    my @IFMETRICKEYS = ifMetricOIDs();
    for my $ifs (@{$params{ifs}}) {

        my $interface;
        if ($ifs == -1) {
            $interface = ''
        } else {
            $interface = '.' . $ifs
        }

        my %ret;
        $ret{Index} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.1' . $interface);
        if (!defined $ret{Index}) {
            $Cisco::SNMP::LASTERROR = "Cannot get ifIndex `$interface'";
            return undef
        }
        # multicasts
        if ($params{$IFMETRICUSERKEYS[0]}) {
            # In
            $ret{$IFMETRICKEYS[0]} = Cisco::SNMP::_snmpwalk($session, '1.3.6.1.2.1.31.1.1.1.2' . $interface);
            if (!defined $ret{$IFMETRICKEYS[0]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[0]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[1]} = Cisco::SNMP::_snmpwalk($session, '1.3.6.1.2.1.31.1.1.1.4' . $interface);
            if (!defined $ret{$IFMETRICKEYS[1]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[1]'";
                return undef
            }
        }
        # broadcasts
        if ($params{$IFMETRICUSERKEYS[1]}) {
            # In
            $ret{$IFMETRICKEYS[2]} = Cisco::SNMP::_snmpwalk($session, '1.3.6.1.2.1.31.1.1.1.3' . $interface);
            if (!defined $ret{$IFMETRICKEYS[2]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[2]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[3]} = Cisco::SNMP::_snmpwalk($session, '1.3.6.1.2.1.31.1.1.1.5' . $interface);
            if (!defined $ret{$IFMETRICKEYS[3]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[3]'";
                return undef
            }
        }
        # octets
        if ($params{$IFMETRICUSERKEYS[2]}) {
            # In
            $ret{$IFMETRICKEYS[4]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.10' . $interface);
            if (!defined $ret{$IFMETRICKEYS[4]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[4]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[5]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.16' . $interface);
            if (!defined $ret{$IFMETRICKEYS[5]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[5]'";
                return undef
            }
        }
        # unicasts
        if ($params{$IFMETRICUSERKEYS[3]}) {
            # In
            $ret{$IFMETRICKEYS[6]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.11' . $interface);
            if (!defined $ret{$IFMETRICKEYS[6]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[6]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[7]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.17' . $interface);
            if (!defined $ret{$IFMETRICKEYS[7]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[7]'";
                return undef
            }
        }
        # discards
        if ($params{$IFMETRICUSERKEYS[4]}) {
            # In
            $ret{$IFMETRICKEYS[8]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.13' . $interface);
            if (!defined $ret{$IFMETRICKEYS[8]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[8]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[9]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.19' . $interface);
            if (!defined $ret{$IFMETRICKEYS[9]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[9]'";
                return undef
            }
        }
        # errors
        if ($params{$IFMETRICUSERKEYS[5]}) {
            # In
            $ret{$IFMETRICKEYS[10]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.14' . $interface);
            if (!defined $ret{$IFMETRICKEYS[10]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[10]'";
                return undef
            }
            # Out
            $ret{$IFMETRICKEYS[11]} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.20' . $interface);
            if (!defined $ret{$IFMETRICKEYS[11]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[11]'";
                return undef
            }
        }
        # unknowns
        if ($params{$IFMETRICUSERKEYS[6]}) {
            # In
            $ret{$IFMETRICKEYS[12]}  = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.15' . $interface);
            if (!defined $ret{$IFMETRICKEYS[12]}) {
                $Cisco::SNMP::LASTERROR = "Cannot get interface `$interface' `$IFMETRICKEYS[12]'";
                return undef
            }
        }

        for my $idx (0..$#{$ret{Index}}) {
            my %IfMetricHash;
            for (0..$#IFMETRICKEYS) {
                $IfMetricHash{$IFMETRICKEYS[$_]}  = $ret{$IFMETRICKEYS[$_]}->[$idx]
            }
            $IfMetric{$ret{Index}->[$idx]} = \%IfMetricHash
        }
    }
    return bless \%IfMetric, $class
}

for (ifMetricOIDs()) {
    Cisco::SNMP::_mk_accessors_hash_1('if', $_)
}

sub interface_utilization {
    my $self  = shift;
    my $class = ref($self) || $self;

    my $session = $self->{_SESSION_};

    my %params = (
        'polling' => 10
    );

    my %args;
    if (@_ != 1) {
        %args = @_;
        for (keys(%args)) {
            if ((/^-?polling$/i) || (/^-?interval$/i)) {
                if (($args{$_} =~ /^\d+$/) && ($args{$_} > 0)) {
                    $params{polling} = $args{$_}
                } else {
                    $Cisco::SNMP::LASTERROR = "Invalid polling interval `$args{$_}'";
                    return undef
                }
            } elsif (/^-?recursive$/i) {
                $params{recur} = $args{$_}
            }
        }
    }

    my $prev;
    if (exists($params{recur}) && (ref($params{recur}) eq __PACKAGE__)) {
        $prev = $params{recur}
    } else {
        if (!defined($prev = $self->interface_metrics(@_))) {
            $Cisco::SNMP::LASTERROR = "Cannot get initial utilization: " . $Cisco::SNMP::LASTERROR;
            return undef
        }
    }
    sleep $params{polling};
    my $curr;
    if (!defined($curr = $self->interface_metrics(@_))) {
        $Cisco::SNMP::LASTERROR = "Cannot get current utilization: " . $Cisco::SNMP::LASTERROR;
        return undef
    }

    my %IfUtil;
    my @IFMETRICKEYS = ifMetricOIDs();
    for my $ifs (sort {$a <=> $b} (keys(%{$prev}))) {
        my %IfUtilHash;
        for (0..$#IFMETRICKEYS) {
            if (($_ == 4) || ($_ == 5)) {
                $IfUtilHash{$IFMETRICKEYS[$_]}  = defined($curr->{$ifs}->{$IFMETRICKEYS[$_]})  ? (($curr->{$ifs}->{$IFMETRICKEYS[$_]}  - $prev->{$ifs}->{$IFMETRICKEYS[$_]}) * 8) / $params{polling} : undef;
            } else {
                $IfUtilHash{$IFMETRICKEYS[$_]}  = defined($curr->{$ifs}->{$IFMETRICKEYS[$_]})  ?  ($curr->{$ifs}->{$IFMETRICKEYS[$_]}  - $prev->{$ifs}->{$IFMETRICKEYS[$_]})      / $params{polling} : undef;
            }
        }
        $IfUtil{$ifs} = \%IfUtilHash
    }
    $prev = bless \%IfUtil, $class;
    return wantarray ? ($prev, $curr) : $prev
}

sub interface_updown {
    my $self = shift;

    my $session = $self->{_SESSION_};

    my %op     = (
        'UP'   => 1,
        'DOWN' => 2
    );
    my %params = (
        'oper' => $op{UP}
    );

    my %args;
    my $oper = 'UP';
    if (@_ == 1) {
        ($params{ifs}) = @_;
        if (!defined($params{ifs} = Cisco::SNMP::_get_range($params{ifs}))) {
            return undef
        }
    } else {
        %args = @_;
        for (keys(%args)) {
            if (/^-?interface(?:s)?$/i) {
                if (!defined($params{ifs} = Cisco::SNMP::_get_range($args{$_}))) {
                    return undef
                }
            } elsif ((/^-?operation$/i) || (/^-?command$/i)) {
                if (exists($op{uc($args{$_})})) {
                    $params{oper} = $op{uc($args{$_})};
                    $oper = uc($args{$_})
                } else {
                    $Cisco::SNMP::LASTERROR = "Invalid operation `$args{$_}'";
                    return undef
                }
            }
        }
    }

    if (!defined $params{ifs}) {
        $params{ifs} = Cisco::SNMP::_snmpwalk($session, _ifOID() . '.1');
        if (!defined $params{ifs}) {
            $Cisco::SNMP::LASTERROR = "Cannot get interfaces to $oper";
            return undef
        }
    }

    my @intf;
    for (@{$params{ifs}}) {
        if (defined $session->set_request(_ifOID() . '.7.' . $_, INTEGER, $params{oper})) {
            push @intf, $_
        } else {
            $Cisco::SNMP::LASTERROR = "Failed to $oper interface $_";
            return undef
        }
    }
    return \@intf
}

no strict 'refs';
# get_ direct
my @OIDS = ifOIDs();
# -3 because last keys (Duplex Name Alias) are different OID
for my $o (0..$#OIDS-3) {
    *{"get_if" . $OIDS[$o]} = sub {
        my $self  = shift;
        my ($val) = @_;

        if (!defined $val) { $val = 0 }
        my $s = $self->session;
        my $r = $s->get_request(
            varbindlist => [_ifOID() . '.' . ($o+1) . '.' . $val]
        );
        return $r->{_ifOID() . '.' . ($o+1) . '.' . $val}
    }
}

sub get_ifDuplex {
    my $self  = shift;
    my ($val) = @_;

    if (!defined $val) { $val = 0 }
    my $s = $self->session;
    my $r = $s->get_request(
        varbindlist => ['1.3.6.1.2.1.10.7.2.1.19.' . $val]
    );
    return $r->{'1.3.6.1.2.1.10.7.2.1.19.' . $val}
}

sub get_ifName {
    my $self  = shift;
    my ($val) = @_;

    if (!defined $val) { $val = 0 }
    my $s = $self->session;
    my $r = $s->get_request(
        varbindlist => ['1.3.6.1.2.1.31.1.1.1.1.' . $val]
    );
    return $r->{'1.3.6.1.2.1.31.1.1.1.1.' . $val}
}

sub get_ifAlias {
    my $self  = shift;
    my ($val) = @_;

    if (!defined $val) { $val = 0 }
    my $s = $self->session;
    my $r = $s->get_request(
        varbindlist => ['1.3.6.1.2.1.31.1.1.1.18.' . $val]
    );
    return $r->{'1.3.6.1.2.1.31.1.1.1.18.' . $val}
}

my %OIDS = _ifMetricOIDVals();
for my $o (keys(%OIDS)) {
    *{"get_if" . $o} = sub {
        my $self  = shift;
        my ($val) = @_;

        if (!defined $val) { $val = 0 }
        my $s = $self->session;
        my $r = $s->get_request(
            varbindlist => [_ifOID() . '.' . $OIDS{$o} . '.' . $val]
        );
        return $r->{_ifOID() . '.' . $OIDS{$o} . '.' . $val}
    }
}

@OIDS = qw(InMulticasts InBroadcasts OutMulticasts OutBroadcasts);
for my $o (0..3) {
    *{"get_if" . $OIDS[$o]} = sub {
        my $self  = shift;
        my ($val) = @_;

        if (!defined $val) { $val = 0 }
        my $s = $self->session;
        my $r = $s->get_request(
            varbindlist => ['1.3.6.1.2.1.31.1.1.1.' . ($o+2) . '.' . $val]
        );
        return $r->{'1.3.6.1.2.1.31.1.1.1.' . ($o+2) . '.' . $val}
    }
}

##################################################
# End Public Module
##################################################

1;

__END__