File Coverage

blib/lib/Catmandu/Plack/unAPI.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	4	4	100.0
condition			n/a
subroutine	11	11	100.0
pod	1	2	50.0
total	58	59	98.3

package Catmandu::Plack::unAPI;

use Catmandu::Sane;
use Catmandu qw(exporter);
use Scalar::Util qw(blessed);
use Plack::App::unAPI;
use Plack::Request;
use Moo;

use parent 'Plack::Component';

our $VERSION = '0.10';

has formats => (
    is      => 'ro',
    default => sub {
        return {
            json => {
                type     => 'application/json',
                exporter => [ 'JSON', pretty => 1 ],
                docs     => 'http://json.org/',
            },
            yaml => {
                type     => 'text/yaml',
                exporter => [ 'YAML' ],
                docs     => 'http://en.wikipedia.org/wiki/YAML',
            }
        }
    }
    # TODO: check via pre-instanciation
);

has query => (
    is      => 'ro',
    default => sub { }
);

has unapi => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        unAPI( map {
            my $format = $_[0]->formats->{$_};
            $_ => [
                $_[0]->format_as_app($format),
                $format->{type},
                docs => $format->{docs},
            ]
        } keys %{$_[0]->formats})
    }
);

sub format_as_app {
    my ($self, $format) = @_;

    sub {
        my ($env) = @_;
        my $req   = Plack::Request->new($env);
        my $id    = $req->param('id');

        my $record = $self->query->($id);
        if (ref $record) {
            my $out;
            my $exporter = exporter( @{ $format->{exporter} }, file => \$out );
            $exporter->add($record);
            $exporter->commit;
            [ 200, [ 'Content-Type' => $format->{type} ] , [ $out ] ];
        } elsif(defined $record) {
            [ 400, [ 'Content-Type' => 'text/plain' ], [ $record ] ];
        } else {
            [ 404, [ 'Content-Type' => 'text/plain' ], [ 'Not Found' ] ];
        }
    }
}

sub call {
    my ($self, $env) = @_;
    $self->unapi->($env);
}

1;
__END__