File Coverage

blib/lib/Catmandu/Importer/CPAN.pm

Criterion	Covered	Total	%
statement	9	19	47.3
branch	0	6	0.0
condition			n/a
subroutine	3	5	60.0
pod			n/a
total	12	30	40.0

package Catmandu::Importer::CPAN;

use Catmandu::Sane;
use MetaCPAN::API::Tiny;
use Moo;

with 'Catmandu::Importer';

our $VERSION = '0.03';

has prefix => (is => 'ro');
has author => (is => 'ro');

# http://api.metacpan.org/v0/release/_mapping
our $RELEASE_FIELDS = [qw(
    abstract archive author authorized date dependency distribution
    download_url first id license maturity name provides resources stat status
    tests version version_numified
)];

has fields => (
    is => 'ro',
    default => sub { [ qw(id date distribution version abstract) ] },
    coerce => sub {
        ref $_[0] ? $_[0]
                  : ($_[0] eq 'all' ? $RELEASE_FIELDS
                                    : [ split /,/, $_[0] ]);
    }
);

has mcpan => (is => 'ro', builder => sub { MetaCPAN::API::Tiny->new });
has filter => (is => 'ro', lazy => 1, builder => 1);

sub _build_filter {
    my $self = $_[0];

    my @filter = { term => { status => 'latest' } };

    if ($self->prefix) {
        push @filter, { prefix => { archive => $self->prefix } };
    }

    if ($self->author) {
        push @filter, { term => { author => $self->author } };
    }

    if (@filter > 1) {
        return { and => \@filter };
    } else {
        return $filter[0];
    }
}

sub generator {
    my $self = $_[0];

    my $result = $self->mcpan->post(
        release => {
            fields => $self->fields,
            filter => $self->filter,
            size   => 1024,
        }
    );

    my @hits = @{$result->{hits}->{hits}};

    return sub {
        my $hit = shift @hits;
        return undef unless $hit;
        return {
            map { $_ => $hit->{fields}->{$_} } @{$self->fields}
        }
    };
}

1;
__END__