File Coverage

blib/lib/Catalyst/Plugin/Log/Handler.pm

Criterion	Covered	Total	%
statement	41	43	95.3
branch	1	2	50.0
condition	1	2	50.0
subroutine	13	14	92.8
pod	0	1	0.0
total	56	62	90.3

package Catalyst::Plugin::Log::Handler;
use strict;
use warnings;

=head1 NAME

Catalyst::Plugin::Log::Handler - Catalyst Plugin for Log::Handler

=head1 VERSION

Version 0.07_01 (developer release)

=cut

our $VERSION = '0.07_01';

use MRO::Compat;

sub setup {
    my $c = shift;

    my $config = $c->config->{'Log::Handler'} || {};

    $c->log((__PACKAGE__ . '::Backend')->new($config));

    return $c->maybe::next::method(@_);
}


package Catalyst::Plugin::Log::Handler::Backend;
use strict;
use warnings;
use base qw(Class::Accessor::Fast);
use Log::Handler 0.63;
use MRO::Compat;

__PACKAGE__->mk_accessors(qw(handler));

my %cat_to_handler_level = (
    debug => 'debug',
    info  => 'info',
    warn  => 'warning',
    error => 'error',
    fatal => 'emergency',
);

{

    while (my ($catlevel, $handlerlevel) = each %cat_to_handler_level) {

	my $logsub = sub {
            my $self = shift;

	    $self->handler->$handlerlevel(@_);
        };

	my $handlerfunc = "is_$handlerlevel";
        my $testsub = sub {
            my $self = shift;

	    $self->handler->$handlerfunc();
        };

	no strict 'refs';
        *{$catlevel}      = $logsub;
        *{"is_$catlevel"} = $testsub;
    }
}

sub new {
    my $class = shift;
    my $self  = $class->next::method();

    my ($config) = @_;

    unless (exists $config->{filename}) {
	warn "There's no Log::Handler->filename in your Catalyst ".
	"app configuration.\n";
    }

    # Log::Handler->new will fail if there's no filename in the conf.  But let's
    # try it anyway to convince the user.

    $self->handler(Log::Handler->new( file => {
	minlevel => 0,
	maxlevel => 7,
	%$config,
    } ));
    return $self;
}

*levels = *enable = *disable = sub { return 0; };

1;
__END__