File Coverage

lib/CallBackery/Plugin/Doc.pm

Criterion	Covered	Total	%
statement	101	106	95.2
branch	6	14	42.8
condition	8	18	44.4
subroutine	15	17	88.2
pod	1	1	100.0
total	131	156	83.9

package CallBackery::Plugin::Doc;
use strict;
use warnings;

# based on Mojolicious::Plugin::PodRenderer

use Mojo::Base 'Mojolicious::Plugin';

use File::Basename 'dirname';
use File::Spec;
use IO::File;
use Mojo::Asset::File;
use Mojo::ByteStream 'b';
use Mojo::DOM;
use Mojo::Util 'url_escape';
use Pod::Simple::HTML;
use Pod::Simple::Search;

# Paths
our @PATHS = map { ($_ , "$_/pods") } @INC;

# "This is my first visit to the Galaxy of Terror and I'd like it to be a
#  pleasant one."
sub register {
  my ($self, $app, $conf) = @_;
  # Config
  $conf ||= {};
  my $name       = $conf->{name}       || 'pod';
  my $preprocess = $conf->{preprocess} || 'ep';
  my $index      = $conf->{index}      || die 'index attribute is required';
  my $root       = $conf->{root}       || die 'root attribute is required';
  my $template   = $conf->{template}   || die 'template attribute is required';

  # Add "pod" handler
  $app->renderer->add_handler(
    $name => sub {
      my ($r, $c, $output, $options) = @_;

      # Preprocess with ep and then render
      return unless $r->handlers->{$preprocess}->($r, $c, $output, $options);
      $$output = _pod_to_html($$output)
    }
  );

  # Add "pod_to_html" helper
  $app->helper(pod_to_html => sub { shift; b(_pod_to_html(@_)) });

  # Perldoc
  $app->routes->any(
      $root.'/*module' => { module => $index } => sub {
      my $self = shift;

      # Find module
      my $module = $self->param('module');
      my $html;
      my $cpan = 'http://search.cpan.org/perldoc';
      $module =~ s/\//\:\:/g;
      my $path;
      $path = Pod::Simple::Search->new->find($module, @PATHS);
      # Redirect to CPAN
      return $self->redirect_to("$cpan?$module")
            unless $path && -r $path;

      # Turn POD into HTML
      my $file = IO::File->new;
      $file->open("< $path");
      $html = _pod_to_html(join '', <$file>);

      # Rewrite links
      my $dom     = Mojo::DOM->new("$html");
      my $perldoc = $self->url_for($root.'/');
      $dom->find('a[href]')->each(
        sub {
          my $attr = shift->attr;
          if ($attr->{href} =~ /^$cpan/) {
            $attr->{href} =~ s/^$cpan\?/$perldoc/;
            $attr->{href} =~ s/%3A%3A/\//gi;
          }
        }
      );

      # Rewrite code sections for syntax highlighting
#      $dom->find('pre')->each(
#        sub {
#          my $attrs = shift->attrs;
#          my $class = $attrs->{class};
#          $attrs->{class} =
#            defined $class ? "$class prettyprint lang-perl" : 'prettyprint lang-perl';
#        }
#      );

      # Rewrite headers
      my $url = $self->req->url->clone;
      $url =~ s/%2F/\//gi;
      my $toc = Mojo::URL->new->fragment('toc');

      my $sections = [];
        for my $e ($dom->find('h1, h2, h3')->each) {
            push @$sections, [] if $e->tag eq 'h1' || !@$sections;
            my $anchor = $e->{id};
            my $link   = Mojo::URL->new->fragment($anchor);
            push @{$sections->[-1]}, my $text = $e->all_text, $link;
            my $permalink = $self->link_to('#' => $link, class => 'permalink');
            $e->content($permalink . $self->link_to($text => $toc, id => $anchor));
        }


      # Try to find a title
      my $title = 'Perldoc';
      $dom->find('h1 + p')->first(sub { $title = shift->text });

      # Combine everything to a proper response
      $self->content_for(perldoc => "$dom");
      $self->content_for(index_link => $root.'/');
      # $self->app->plugins->run_hook(before_perldoc => $self);
      $self->render(
        inline   => $template,
        title    => $title,
        sections => $sections
      );
      $self->res->headers->content_type('text/html;charset="UTF-8"');
    }
  );
  return;
}

sub _pod_to_html {
  my $pod = shift;
  return unless defined $pod;

  # Block
  $pod = $pod->() if ref $pod eq 'CODE';

  # Parser
  my $parser = Pod::Simple::HTML->new;
  $parser->force_title('');
  $parser->html_header_before_title('');
  $parser->html_header_after_title('');
  $parser->html_footer('');
  $parser->index(0);

  # Parse
  my $output;
  $parser->output_string(\$output);
  eval { $parser->parse_string_document("$pod") };
  return $@ if $@;

  # Filter
  $output =~ s/<\/a>\n//g;
  $output =~ s/(.*?)<\/a>/$1/sg;

  return $output;
}

1;

__END__