File Coverage

lib/CSS/Watcher/ParserLess.pm

Criterion	Covered	Total	%
statement	23	44	52.2
branch	0	16	0.0
condition			n/a
subroutine	8	10	80.0
pod	0	3	0.0
total	31	73	42.4

package CSS::Watcher::ParserLess;

use warnings;
use strict;

use Path::Tiny;
use File::Which;
use IPC::Run3;
use Log::Log4perl qw(:easy);

use CSS::Watcher::Parser;

sub new {
    my $class = shift;

    return bless ({}, $class);
}

sub parse_less {
    my $self = shift;
    my $filename = shift;

    my $cmd = [ $self->executable,
                '--no-color',
                $filename
            ];
    my $err;
    my $out;
    local ($!, $?) = (0, -1);
    IPC::Run3::run3($cmd, undef, \$out, \$err, {return_if_system_error => 1});

    if (!$?) {
       $err = '';
    } elsif ($! == 2) {
        ERROR sprintf "Cannot execute '%s'. See http://lesscss.org/#usage", $cmd->[0];
    } else {
        DEBUG sprintf "Failed to run \"%s\":\n  %s\n%s", join(' ', @$cmd), $err, $out;
        $out = '';
    }

    my ($classes, $ids) = ({}, {});
    if ($out ne '') {
        INFO sprintf '%s: lessc done, parsing generated CSS', path($filename)->basename;
        ($classes, $ids) = CSS::Watcher::Parser->new->parse_css($out);
    }

    # Find dependencies for this less file.
    my @requiries;
    foreach (path($filename)->lines_utf8()) {
        (m/^\s*?\@import\s+"(.*?.less)"/) ? push @requiries, $1 :
        (m/^\s*?\@import\s+"(.*?.css)"/)  ? push @requiries, $1 :
        (m/^\s*?\@import\s+"(.*?)"/)  ? push @requiries, $1 . '.less' : 1;
    }

    INFO sprintf "%s: imports: %s", path($filename)->basename, join(', ', @requiries)  if (@requiries);

    return ($classes, $ids, \@requiries);
}

sub executable {
    File::Which::which('lessc') || 'lessc' ;
}

1;

__END__