File Coverage

blib/lib/CSS/Struct/Output/Structure.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	5	6	83.3
condition			n/a
subroutine	15	15	100.0
pod	1	1	100.0
total	80	81	98.7

package CSS::Struct::Output::Structure;

use base qw(CSS::Struct::Output);
use strict;
use warnings;

use Error::Pure qw(err);

our $VERSION = 0.02;

sub flush {
	my ($self, $reset_flag) = @_;

	my $ouf = $self->{'output_handler'};

	# Text output.
	my $ret_ar;
	if ($ouf) {
		foreach my $line_ar (@{$self->{'flush_code'}}) {
			my $line = "['";
			$line .= join "', '", @{$line_ar};
			$line .= "']".$self->{'output_sep'};
			no warnings;
			print {$ouf} $line
				or err 'Cannot write to output handler.';
		}

	# Structure.
	} else {
		$ret_ar = $self->{'flush_code'};
	}

	# Reset.
	if ($reset_flag) {
		$self->reset;
	}

	return $ret_ar;
}

# At-rules.
sub _put_at_rules {
	my ($self, $at_rule, $value) = @_;

	$self->_put_structure('a', $at_rule, $value);

	return;
}

# Comment.
sub _put_comment {
	my ($self, @comments) = @_;

	$self->_put_structure('c', @comments);

	return;
}

# Definition.
sub _put_definition {
	my ($self, $key, $value) = @_;

	$self->_put_structure('d', $key, $value);

	return;
}

# End of selector.
sub _put_end_of_selector {
	my $self = shift;

	$self->_put_structure('e');

	return;
}

# Instruction.
sub _put_instruction {
	my ($self, $target, $code) = @_;

	$self->_put_structure('i', $target, $code);

	return;
}

# Raw data.
sub _put_raw {
	my ($self, @raw_data) = @_;

	$self->_put_structure('r', @raw_data);

	return;
}

# Selectors.
sub _put_selector {
	my ($self, $selector) = @_;

	$self->_put_structure('s', $selector);

	return;
}

# Put common structure.
sub _put_structure {
	my ($self, @struct) = @_;

	push @{$self->{'flush_code'}}, \@struct;

	return;
}

# Reset flush code.
sub _reset_flush_code {
	my $self = shift;

	$self->{'flush_code'} = undef;

	return;
}

1;

__END__