File Coverage

blib/lib/CSS/Struct/Output/Indent/ANSIColor.pm

Criterion	Covered	Total	%
statement	18	93	19.3
branch	0	28	0.0
condition			n/a
subroutine	6	15	40.0
pod			n/a
total	24	136	17.6

package CSS::Struct::Output::Indent::ANSIColor;

use base qw(CSS::Struct::Output::Indent);
use strict;
use warnings;

use Indent;
use Readonly;
use Term::ANSIColor;

# Constants.
Readonly::Scalar my $EMPTY_STR => q{};
Readonly::Scalar my $SPACE => q{ };

our $CSS_COMMENT = 'r064g085b107';
our $CSS_SELECTOR_ELEMENT = 'red';
our $CSS_SELECTOR_CLASS = 'r255g156b000';
our $CSS_SELECTOR_ID = 'r255g156b000';
our $CSS_AT_RULE_KEYWORD = 'r255g156b000';
our $CSS_AT_RULE_VALUE = 'yellow';
our $CSS_DEFINITION_KEY = 'green';
our $CSS_DEFINITION_KEY_PREFIX = 'blue';
our $CSS_DEFINITION_VALUE_NUMBER = 'red';
our $CSS_DEFINITION_VALUE_STRING = 'blue';

our $VERSION = 0.02;

# At-rules.
sub _put_at_rules {
	my ($self, $at_rule, $value) = @_;
	push @{$self->{'flush_code'}}, color($CSS_AT_RULE_KEYWORD).$at_rule.color('reset').
		' "'.color($CSS_AT_RULE_VALUE).$value.color('reset').'";';
	$self->{'processed'} = 1;
	return;
}

# Comment.
sub _put_comment {
	my ($self, @comments) = @_;
	if (! $self->{'skip_comments'}) {
		push @comments, $SPACE.$self->{'comment_delimeters'}->[1];
		unshift @comments, $self->{'comment_delimeters'}->[0].$SPACE;
		if ($self->{'processed'}) {
			push @{$self->{'flush_code'}}, $EMPTY_STR;
		}
		my $comment = color($CSS_COMMENT).
			(join $EMPTY_STR, @comments).
			color('reset');
		if (@{$self->{'tmp_code'}}) {
			my $sep = $EMPTY_STR;
			if ($self->{'comment_after_selector'} == 0) {
				$sep = $self->{'output_sep'};
				pop @{$self->{'tmp_code'}};
			}
			push @{$self->{'tmp_code'}}, ($sep) x 2, $comment,
				$self->{'output_sep'};
			$self->{'comment_after_selector'} += 4;
		} else {
			push @{$self->{'flush_code'}},
				$self->{'indent'}->get.$comment;
		}
		$self->{'processed'} = 0;
	}
	return;
}

# Definition.
sub _put_definition {
	my ($self, $key, $value) = @_;

	$self->_check_opened_selector;
	$self->_flush_tmp;
	push @{$self->{'flush_code'}},
		$self->{'indent'}->get.
		$self->_colorize_definition_key($key).
		':'.
		$SPACE.
		$self->_colorize_definition_value($value).
		';';
	$self->{'processed'} = 1;

	return;
}

# Selectors.
sub _put_selector {
	my ($self, $selector) = @_;

	$selector = $self->_split_selector($selector);

	push @{$self->{'tmp_code'}}, $selector, ',', ' ';
	$self->{'comment_after_selector'} = 0;
	$self->{'open_selector'} = 1;

	return;
}

sub _split_selector {
	my ($self, $selector) = @_;

	my @selector;
	if ($selector =~ m/\s+/ms) {
		@selector = split m/\s+/ms, $selector;
	} else {
		@selector = $selector;
	}

	my $ret_selector;
	foreach my $one_selector (@selector) {
		if (defined $ret_selector) {
			$ret_selector .= ' ';
		}
		$ret_selector .= $self->_detect_selector($one_selector);
	}

	return $ret_selector;
}

sub _detect_selector {
	my ($self, $selector) = @_;

	if ($selector =~ m/^\./ms) {
		$selector = $self->_colorize_selector($selector, 'class');
	} elsif ($selector =~ m/^(.*)(#.*)$/ms) {
		$selector = $self->_colorize_selector($1, 'element').
			$self->_colorize_selector($2, 'id');
	} elsif ($selector =~ m/^(.*)(\..*)$/ms) {
		$selector = $self->_colorize_selector($1, 'element').
			$self->_colorize_selector($2, 'class');
	} else {
		$selector = $self->_colorize_selector($selector, 'element');
	}

	return $selector;
}

sub _colorize_selector {
	my ($self, $selector, $type) = @_;

	if ($type eq 'element') {
		$selector = color($CSS_SELECTOR_ELEMENT).$selector.color('reset');
	} elsif ($type eq 'class') {
		$selector = color($CSS_SELECTOR_CLASS).$selector.color('reset');
	} elsif ($type eq 'id') {
		$selector = color($CSS_SELECTOR_ID).$selector.color('reset');
	}

	return $selector;
}

sub _colorize_definition_key {
	my ($self, $key) = @_;

	if ($key =~ m/^--/ms) {
		$key = color($CSS_DEFINITION_KEY_PREFIX).$key.color('reset');
	} else {
		$key = color($CSS_DEFINITION_KEY).$key.color('reset');
	}

	return $key;
}

sub _colorize_definition_value {
	my ($self, $value) = @_;

	if ($value =~ m/^\d+$/ms) {
		$value = color($CSS_DEFINITION_VALUE_NUMBER).$value.color('reset');
	} else {
		$value = color($CSS_DEFINITION_VALUE_STRING).$value.color('reset');
	}

	return $value;
}

1;

__END__