File Coverage

blib/lib/CSS/Scopifier.pm

Criterion	Covered	Total	%
statement	48	51	94.1
branch	10	16	62.5
condition	3	5	60.0
subroutine	6	6	100.0
pod	2	2	100.0
total	69	80	86.2

package CSS::Scopifier;
use strict;
use warnings;

# ABSTRACT: Prepends CSS selectors to apply scope/context

our $VERSION = 0.03;

use CSS::Tiny 1.19;

use Moo;
extends 'CSS::Tiny';

sub scopify {
  my ($self, $selector, @arg) = @_;
  my %opt = ref($arg[0]) ? %{$arg[0]} : @arg;

  die "scopify() requires string selector argument"
    unless ($selector && ! ref($selector));

  # Merge specified selectors into the root/scoped selector. Useful
  # with  merge => ['html','body'] if scopifying a base css file
  my $root_sel;
  if($opt{merge}) {
    my @list = ref $opt{merge} ? @{$opt{merge}} : ($opt{merge});
    $root_sel = {};
    %$root_sel = ( %$root_sel, %$_ ) for (
      map { delete $self->{$_} }
      grep { exists $self->{$_} }
      @list
    );
  }

	$self->{"$selector $_"} = delete $self->{$_} for (keys %$self);
  $self->{$selector} = $root_sel if ($root_sel);

  return 1;
}

# Redefining read_string() until CSS::Tiny bug [rt.cpan.org #87261] is fixed
sub read_string {
    my $self = ref $_[0] ? shift : bless {}, shift;

    # Flatten whitespace and remove /* comment */ style comments
    my $string = shift;
    $string =~ tr/\n\t/  /;
    $string =~ s!/\*.*?\*\/!!g;

    # Split into styles
    foreach ( grep { /\S/ } split /(?<=\})/, $string ) {
        unless ( /^\s*([^{]+?)\s*\{(.*)\}\s*$/ ) {
            return $self->_error( "Invalid or unexpected style data '$_'" );
        }

        # Split in such a way as to support grouped styles
        my $style      = $1;
        my $properties = $2;
        $style =~ s/\s{2,}/ /g;
        my @styles = grep { s/\s+/ /g; 1; } grep { /\S/ } split /\s*,\s*/, $style;
        foreach ( @styles ) { $self->{$_} ||= {} }

        # Split into properties
        foreach ( grep { /\S/ } split /\;/, $properties ) {
            unless ( /^\s*(\*?[\w._-]+)\s*:\s*(.*?)\s*$/ ) { #<-- updated regex to support starting with '*'
                return $self->_error( "Invalid or unexpected property '$_' in style '$style'" );
            }
            foreach ( @styles ) { $self->{$_}->{lc $1} = $2 }
        }
    }

    $self
}


1;

__END__