File Coverage

blib/lib/CPAN/02Packages/Search.pm

Criterion	Covered	Total	%
statement	15	46	32.6
branch	0	18	0.0
condition	0	6	0.0
subroutine	5	9	55.5
pod	0	2	0.0
total	20	81	24.6

package CPAN::02Packages::Search;
use strict;
use warnings;

use IO::Handle;
use Search::Dict ();
use Tie::Handle::SkipHeader;

our $VERSION = '0.001';

sub new {
    my ($class, %argv) = @_;
    my $file = $argv{file};
    my $skip_header = exists $argv{skip_header} ? $argv{skip_header} : 1;
    my $self = bless { file => $file, skip_header => $skip_header }, $class;
    $self->_fh;
    $self;
}

sub _fh {
    my $self = shift;
    return $self->{fh} if defined $self->{pid} && $self->{pid} == $$;
    my $file = $self->{file};
    if ($self->{skip_header}) {
        my $fh = IO::Handle->new;
        tie *$fh, 'Tie::Handle::SkipHeader', '<', $file or die "$!: $file\n";
        $self->{fh} = $fh;
    } else {
        open my $fh, "<", $file or die "$!: $file\n";
        $self->{fh} = $fh;
    }
    $self->{pid} = $$;
    $self->{fh};
}

sub search {
    my ($self, $package) = @_;
    my $fh = $self->_fh;
    seek $fh, 0, 0;
    my $pos = Search::Dict::look $fh, $package, { xfrm => \&_xform_package, fold => 1 };
    return if $pos == -1 || eof $fh;
    while (my $line = <$fh>) {
        last if $line !~ /\A\Q$package\E\s+/i;
        chomp $line;
        my ($_package, $version, $path) = split /\s+/, $line, 4;
        if ($package eq $_package) {
            $version = undef if $version eq 'undef';
            return { version => $version, path => $path };
        }
    }
    return;
}

sub _xform_package { (split " ", $_[0], 2)[0] }

1;
__END__