File Coverage

blib/lib/CMS/Drupal/Modules/MembershipEntity/Stats.pm

Criterion	Covered	Total	%
statement	72	255	28.2
branch	14	78	17.9
condition	0	12	0.0
subroutine	15	27	55.5
pod	18	18	100.0
total	119	390	30.5

package CMS::Drupal::Modules::MembershipEntity::Stats;
$CMS::Drupal::Modules::MembershipEntity::Stats::VERSION = '0.96';
# ABSTRACT: Generate statistics about MembershipEntity memberships on a Drupal site.

use strict;
use warnings;

use Moo;
use Types::Standard qw/ :all /;
use base 'Exporter::Tiny';
our @EXPORT = qw/
  count_total_memberships
  count_expired_memberships
  count_active_memberships
  count_cancelled_memberships
  count_pending_memberships
  count_set_were_renewal_memberships
  count_daily_were_renewal_memberships
  count_daily_total_memberships
  count_daily_term_expirations
  count_daily_term_activations
  count_daily_new_memberships
  count_daily_new_terms
  count_daily_renewals
  count_daily_active_memberships
  build_date_range
  time_plus_one_day
  datetime_plus_one_day
  report_yesterday
/;

use Time::Local;
use DateTime::Event::Recurrence;

use CMS::Drupal::Modules::MembershipEntity::Membership;

use Carp qw/ carp croak /;

has dbh    => ( is => 'ro', isa => InstanceOf['DBI::db'], required => 1 );
has prefix => ( is => 'ro', isa => Maybe[Str] );


sub count_total_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    $self->{'stats'}->{'_count_total_memberships'} = scalar keys %{ $self->{'_memberships'} };
  } else {
    my $sql = q{ SELECT COUNT(mid) FROM membership_entity };
    $self->{'stats'}->{'_count_total_memberships'} = $self->{'dbh'}->selectrow_array( $sql );
  }
  return $self->{'stats'}->{'_count_total_memberships'};
}


sub count_expired_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    my $count = 0;
    while ( my ($mid, $mem) = each %{ $self->{'_memberships'} } ) {
      $count++ if $mem->is_expired;
    }
    $self->{'_count_expired_memberships'} = $count;
  } else {
    my $sql = q{ select count(mid) from membership_entity where status = 0 };
    $self->{'_count_expired_memberships'} = $self->{'dbh'}->selectrow_array( $sql );
  }
  return $self->{'_count_expired_memberships'};
}


sub count_active_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    my $count = 0;
    while ( my ($mid, $mem) = each %{ $self->{'_memberships'} } ) {
      $count++ if $mem->is_active;
    }
    $self->{'_count_active_memberships'} = $count;
  } else {
    my $sql = q{ SELECT COUNT(mid) FROM membership_entity WHERE status = 1 };
    $self->{'_count_active_memberships'} = $self->{'dbh'}->selectrow_array( $sql );
  }
  return $self->{'_count_active_memberships'};
}


sub count_cancelled_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    my $count = 0;
    while ( my ($mid, $mem) = each %{ $self->{'_memberships'} } ) {
      $count++ if $mem->is_cancelled;
    }
    $self->{'_count_cancelled_memberships'} = $count;
  } else {
    my $sql = q{ SELECT COUNT(mid) FROM membership_entity WHERE status = 2 };
    $self->{'_count_cancelled_memberships'} = $self->{'dbh'}->selectrow_array( $sql );
  }
  return $self->{'_count_cancelled_memberships'};
}


sub count_pending_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    my $count = 0;
    while ( my ($mid, $mem) = each %{ $self->{'_memberships'} } ) {
      $count++ if $mem->is_pending;
    }
    $self->{'_count_pending_memberships'} = $count;
  } else {
    my $sql = q{ select count(mid) from membership_entity where status = 3 };
    $self->{'_count_pending_memberships'} = $self->{'dbh'}->selectrow_array( $sql );
  }
  return $self->{'_count_pending_memberships'};
}


sub count_set_were_renewal_memberships {
  my $self = shift;
  if ($self->{'_memberships'}) {
    $self->{'_count_were_renewal_memberships'} = 0;
    while ( my ($mid, $mem) = each %{ $self->{'_memberships'} } ) {
      if ( $mem->current_was_renewal ) {
        $self->{'_count_were_renewal_memberships'}++;
      }
    }
  } else {
    croak qq/
      Died.
      count_were_renewal_memberships() must be called with a set of
      Memberships. You probably forgot to call fetch_memberships()
      on your MembershipEntity object before calling this method.
    /;
  }
  return $self->{'_count_were_renewal_memberships'};
}


sub count_daily_were_renewal_memberships {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  ## First get all the terms
  my $sql = qq/
    SELECT mid, id AS tid, start, end
    FROM membership_entity_term
  /;

  my %current_mids;
  my %current_tids;
  my %ordered_terms;

  ## get all the terms from the DB
  my $terms = $self->{'dbh'}->selectall_hashref( $sql, 'tid' );

  foreach my $term ( values %{ $terms } ) {
    # indexed by mid, but terms indexed by start time for easier sorting
    $ordered_terms{ $term->{'mid'} }->{ $term->{'start'} } = $term->{'tid'};
  }

  ## loop through the dates
  foreach my $datetime ( @dates ) {

    ## find the ones that were current on the date
    foreach my $term ( values %{ $terms } ) {
      next unless $datetime gt $term->{'start'} and $term->{'end'} gt $datetime;

      $current_mids{ $term->{'mid'} }++;
      $current_tids{ $term->{'tid'} }++;
    }

    # Now process each mid
    foreach my $mid ( keys %ordered_terms ) {

      # only keep it if it had a current term, i.e. was active
      if ( ! exists $current_mids{ $mid } ) {
        delete $ordered_terms{ $mid };
        next;
      }

      # only keep it if it has at least two terms
      if ( scalar keys %{ $ordered_terms{ $mid } } < 2 ) {
        delete $ordered_terms{ $mid };
        next;
      }
    }

    # if the mem is still here, it has a current term and more than one term.
    # shift the earliest one off; the rest are renewals; is one of them current?
    my %were_renewal_memberships;

    foreach my $mid ( keys %ordered_terms ) {

      my $term_count = 0;

      foreach my $start (sort keys %{ $ordered_terms{ $mid } } ) {
        $term_count++;
        next if $term_count == 1;

        if ( exists $current_tids{ $ordered_terms{ $mid }->{ $start } } ) {
          $were_renewal_memberships{ $mid } = 1;
        }
      }
    }

    $counts{ $datetime } = scalar keys %were_renewal_memberships;
  }

  return (scalar keys %counts == 1) ?
               $counts{ $dates[0] } :
               \%counts;

} # end sub


sub count_daily_term_expirations {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(DISTINCT mid)
    FROM membership_entity_term
    WHERE end >= ?
    AND end < ?
    AND status NOT IN (2,3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $datetime (@dates) {
    $sth->execute( $datetime, $self->datetime_plus_one_day( $datetime ) );
    $counts{ $datetime } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
               $counts{ $dates[0] } :
               \%counts;

} # end sub


sub count_daily_term_activations {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(DISTINCT mid)
    FROM membership_entity_term
    WHERE start >= ?
    AND start < ?
    AND status NOT IN (2,3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $datetime (@dates) {
    $sth->execute( $datetime, $self->datetime_plus_one_day( $datetime ) );
    $counts{ $datetime } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
              $counts{ $dates[0] } :
              \%counts;

} # end sub


sub count_daily_new_memberships {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(DISTINCT mid)
    FROM membership_entity
    WHERE created >= ?
    AND created < ?
    AND status NOT IN (3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $datetime (@dates) {
    my ( $start, $over ) = $self->time_plus_one_day( $datetime );
    $sth->execute( $start, $over );
    $counts{ $datetime } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
              $counts{ $dates[0] } :
              \%counts;

} # end sub


sub count_daily_new_terms {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(DISTINCT mid)
    FROM membership_entity_term
    WHERE created >= ?
    AND created < ?
    AND status NOT IN (3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $datetime (@dates) {
    my ( $start, $over ) = $self->time_plus_one_day( $datetime );
    $sth->execute( $start, $over );
    $counts{ $datetime } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
              $counts{ $dates[0] } :
              \%counts;

} # end sub



sub count_daily_renewals {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql1 = qq/
    SELECT id, mid
    FROM membership_entity_term
    WHERE created >= ?
    AND created < ?
    AND status NOT IN (3)
  /;

  my $sth1 = $self->{'dbh'}->prepare( $sql1 );

  my $sql2 = qq/
    SELECT id
    FROM membership_entity_term
    WHERE mid = ?
  /;

  my $sth2 = $self->{'dbh'}->prepare( $sql2 );

  foreach my $datetime (@dates) {
    $counts{ $datetime } = 0;
    my ( $start, $over ) = $self->time_plus_one_day( $datetime );
    $sth1->execute( $start, $over );
    while ( my ($id, $mid) = $sth1->fetchrow_array ) {
      my $was_renewal = 0;
      $sth2->execute( $mid );
      for ( $sth2->fetchrow_array ) {
        $was_renewal = 1 if $_ < $id;
      }
      $counts{ $datetime } += $was_renewal;
    }
  }

  return (scalar keys %counts == 1) ?
            $counts{ $dates[0] } :
            \%counts;

} # end sub


sub count_daily_active_memberships {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(DISTINCT mid)
    FROM membership_entity_term
    WHERE start <= ? AND end > ?
    AND status NOT IN (2,3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $date (@dates) {
    $sth->execute( $date, $date );
    $counts{ $date } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
           $counts{ $dates[0] } :
           \%counts;

} # end sub


sub count_daily_total_memberships {
  my $self = shift;
  my @dates = @_;
  my %counts;

  carp qq/
    Warning!
    Called a count_daily_ method with no dates. This will return nothing!
  / if ! @dates;

  my $sql = qq/
    SELECT COUNT(mid)
    FROM membership_entity
    WHERE created <= ?
    AND status NOT IN (3)
  /;

  my $sth = $self->{'dbh'}->prepare( $sql );

  foreach my $datetime (@dates) {
    my ( $start, $over ) = $self->time_plus_one_day( $datetime );
    $sth->execute( $over );
    $counts{ $datetime } = $sth->fetchrow_array;
  }

  return (scalar keys %counts == 1) ?
              $counts{ $dates[0] } :
              \%counts;

} # end sub


##################################################
##
## Utility subs
##



sub build_date_range {

  my $self      = shift;
  my $opt_start = shift;
  my $opt_end   = shift;

  my $dt_start;
  if ( ! $opt_start or $opt_start !~ m/[0-9]{4}-[0-9]{2}-[0-9]{2}/) {
    croak qq/
      Died.
      build_date_range() requires a beginning date in format 'YYYY-MM-DD'.
    /;
  } else {
    my ($y,$m,$d) = split( '-', $opt_start);
    $dt_start = DateTime->new( year => $y, month => $m, day => $d );
  }
  $dt_start->set_time_zone('UTC');

  my $dt_end;
  if ( $opt_end ) {
    if ( $opt_end !~ m/[0-9]{4}-[0-9]{2}-[0-9]{2}/) {
      croak qq/
        Died.
        build_date_range() requires that the end date,
        if supplied, be in the format 'YYYY-MM-DD'.
      /;
    } else {
      my ($y,$m,$d) = split( '-', $opt_end);
      $dt_end = DateTime->new( year => $y, month => $m, day => $d );
    }
  } else {
    # default to today;
    $dt_end = DateTime->now;
    $dt_end->set_hour('00');
    $dt_end->set_minute('00');
    $dt_end->set_second('00');
  }
  $dt_end->set_time_zone('UTC');

  my $set = DateTime::Event::Recurrence->daily();
  my $itr = $set->iterator( start => $dt_start, end => $dt_end );

  my @dates;

  while ( my $dt = $itr->next ) {
    push @dates, $dt->datetime;
  }

  return \@dates;

} # end sub


sub datetime_plus_one_day {
  my $self = shift;
  my $datetime = shift;

  if ( ! $datetime or $datetime !~ m/[0-9]{4}-[0-9]{2}-[0-9]{2}/ ) {
    croak qq/
      Died.
      datetime_plus_one() requires a datetime
      in ISO-ish format (YYYY-MM-DDTHH:MM:SS).
    /;
  }

  my ($y, $m, $d) = split /[-| |T|:]/, $datetime;
  return DateTime->new( year => $y, month => $m, day => $d )
                   ->set_time_zone( 'UTC' )
                     ->clone()
                       ->add( days => 1 )
                         ->datetime();

} # end sub



sub time_plus_one_day {
  my $self = shift;
  my $datetime = shift;

  if ( ! $datetime or $datetime !~ m/[0-9]{4}-[0-9]{2}-[0-9]{2}/ ) {
    croak qq/
      Died.
      time_plus_one() requires a datetime in
      ISO-ish format (YYYY-MM-DDTHH:MM:SS).
    /;
  }

  my @dateparts = reverse ( split /[-| |T|:]/, $datetime );
  $dateparts[4]--;
  my $time = timelocal( @dateparts );
  my $plus_one = ($time + (24*3600));

  return( $time, $plus_one );

} # end sub


sub report_yesterday {
  my $self = shift;
  my %args = @_;

  my %methods = map { $_ => 1 } ( qw/
    count_daily_total_memberships
    count_daily_total_memberships
    count_daily_term_expirations
    count_daily_term_activations
    count_daily_new_memberships
    count_daily_new_terms
    count_daily_active_memberships
    count_daily_renewals
    count_daily_were_renewal_memberships
  /);

  if ( $args{'exclude'} ) {
    delete $methods{ $_ } for @{ $args{'exclude'} };
  }

  my $yesterday = DateTime->now()
                            ->clone()
                              ->subtract(days => 1)
                                ->set( hour => 0, minute => 0, second => 0 )
                                  ->datetime();

  my %data;

  for ( keys %methods ) {
    $data{ $_ } = $self->$_( $yesterday );
  }

  $data{ 'date' } = $yesterday;

  return \%data;

} # end sub


1; ## return true to end package CMS::Drupal::Modules::MembershipEntity

__END__