File Coverage

blib/lib/CHI/Cascade/Rule.pm

Criterion	Covered	Total	%
statement	46	59	77.9
branch	17	32	53.1
condition	5	13	38.4
subroutine	12	15	80.0
pod	7	11	63.6
total	87	130	66.9

package CHI::Cascade::Rule;

use strict;
use warnings;
use v5.10;

use Scalar::Util 'weaken';

sub new {
    my ($class, %opts) = @_;

    my $from = ref($class) ? $class : \%opts;

    $opts{depends} = [ defined( $opts{depends} ) ? ( $opts{depends} ) : () ]
      unless ref( $opts{depends} );

    # To do clone or new object
    my $self = bless {
        map( { $_ => $from->{$_} }
          grep { exists $from->{$_} }
          qw( target depends depends_catch code params busy_lock cascade recomputed actual_term ttl value_expires ) ),
        qr_params       => [],
        matched_target  => undef
    }, ref($class) || $class;

    if ( $opts{run_instance} ) {
        $self->{run_instance} = $opts{run_instance};
        weaken $self->{run_instance};   # It is against memory leaks
    }

    weaken $self->{cascade};            # It is against memory leaks
    $self->{resolved_depends} = undef;

    $self;
}

sub qr_params {
    my $self = shift;

    if (@_) {
        $self->{qr_params} = [ @_ ];
    }
    else {
        return @{ $self->{qr_params} };
    }
}

sub depends {
    my $self = shift;

    return $self->{resolved_depends}
      if $self->{resolved_depends};

    if ( ref( $self->{depends} ) eq 'CODE' ) {
        my $res = $self->{depends}->( $self, $self->qr_params );

        $self->{resolved_depends} = ref($res) eq 'ARRAY' ? [ @$res ] : [ $res ];
    }
    else {
        $self->{resolved_depends} = [ @{ $self->{depends} } ];
    }

    for ( @{ $self->{resolved_depends} } ) {
        $_ = $_->( $self, $self->qr_params )
          if ( ref eq 'CODE' );
    }

    $self->{resolved_depends};
}

sub value_expires {
    my $self = shift;

    if (@_) {
        $self->{value_expires} = $_[0];
        return $self;
    }
    ( ref $self->{value_expires} eq 'CODE' ? $self->{value_expires}->( $self ) : $self->{value_expires} ) // 'never';
}

sub target_expires {
    my ( $self, $trg_obj ) = @_;

    $trg_obj->locked
        ?
        $self->{busy_lock} || $self->{cascade}{busy_lock} || 'never'
        :
        $trg_obj->expires // $trg_obj->expires( $self->value_expires );
}

sub ttl {
    my $self = shift;

    return undef
      unless exists $self->{ttl};

    $self->{ttl_time} && return $self->{ttl_time};

    if ( ref $self->{ttl} eq 'ARRAY' && @{ $self->{ttl} } == 2 ) {
        return $self->{ttl_time} = rand( $self->{ttl}[1] - $self->{ttl}[0] ) + $self->{ttl}[0];
    }
    elsif ( ref $self->{ttl} eq 'CODE' ) {
        return $self->{ttl_time} = $self->{ttl}->( $self, $self->qr_params );
    }

    return undef;
}

sub target      { shift->{matched_target}       }
sub params      { shift->{params}               }
sub cascade     { shift->{cascade}              }
sub dep_values  { shift->{dep_values}           }
sub stash       { shift->{run_instance}{stash}  }

1;
__END__