File Coverage

blib/lib/CGI/ACL.pm

Criterion	Covered	Total	%
statement	61	75	81.3
branch	22	36	61.1
condition	4	9	44.4
subroutine	10	10	100.0
pod	4	4	100.0
total	101	134	75.3

package CGI::ACL;

# Author Nigel Horne: [e-mail]
# Copyright (C) 2017, Nigel Horne

# Usage is subject to licence terms.
# The licence terms of this software are as follows:
# Personal single user, single computer use: GPL2
# All other users (including Commercial, Charity, Educational, Government)
#	must apply in writing for a licence for use from Nigel Horne at the
#	above e-mail.

use 5.006_001;
use warnings;
use strict;
use namespace::clean;
use Carp;
use Net::CIDR;

=head1 NAME

CGI::ACL - Decide whether to allow a client to run this script

=head1 VERSION

Version 0.02

=cut

our $VERSION = '0.02';

=head1 SYNOPSIS

Does what it says on the tin.

    use CGI::Info;
    use CGI::ACL;

    my $acl = CGI::ACL->new();
    # ...
    my $denied = $acl->all_denied(info => CGI::Info->new());

=head1 SUBROUTINES/METHODS

=head2 new

Creates a CGI::ACL object.

=cut

sub new {
	my $proto = shift;
	my $class = ref($proto) || $proto;

	return unless(defined($class));

	my %args = (ref($_[0]) eq 'HASH') ? %{$_[0]} : @_;

	return bless { }, $class;
}

=head2 allow_ip

Give an IP (or CIDR) that we allow to connect to us

    use CGI::ACL;

    # Allow Google to connect to us
    my $acl = CGI::ACL->new()->allow_ip(ip => '8.35.80.39');

=cut

sub allow_ip {
	my $self = shift;
	my %params;

	if(ref($_[0]) eq 'HASH') {
		%params = %{$_[0]};
	} elsif(@_ % 2 == 0) {
		%params = @_;
	} else {
		$params{'ip'} = shift;
	}

	if(!defined($params{'ip'})) {
		Carp::carp 'Usage: allow_ip($ip_address)';
	} else {
		$self->{_allowed_ips}->{$params{'ip'}} = 1;
	}
	return $self;
}

=head2 deny_country

Give a country, or a reference to a list of countries, that we will not allow to access us

    use CGI::ACL;

    # Don't allow the UK to connect to us
    my $acl = CGI::ACL->new()->deny_country('UK');

=cut

sub deny_country {
	my $self = shift;
	my %params;

	if(ref($_[0]) eq 'HASH') {
		%params = %{$_[0]};
	} elsif(@_ % 2 == 0) {
		%params = @_;
	} else {
		$params{'country'} = shift;
	}

	if(!defined($params{'country'})) {
		Carp::carp 'Usage: deny_country($country)';
	} else {
		# This shenanegans allows country to be a scalar or list
		my $c = $params{'country'};
		if(ref($c) eq 'ARRAY') {
			foreach my $country(@{$c}) {
				$self->{_deny_countries}->{lc($country)} = 1;
			}
		} else {
			$self->{_deny_countries}->{lc($c)} = 1;
		}
	}
	return $self;
}

=head2 all_denied

If any of the restrictions return false, return false, which should allow access

    use CGI::Info;
    use CGI::Lingua;
    use CGI::ACL;

    # Allow Google to connect to us
    my $acl = CGI::ACL->new()->allow_ip(ip => '8.35.80.39');

    if($acl->all_denied(info => CGI::Info->new())) {
    	print 'You are not allowed to view this site';
	return;
    }

    $acl = CGI::ACL->new()->deny_country(country => 'br');

    if($acl->all_denied(lingua => CGI::Lingua->new(supported => ['en']))) {
    	print 'Brazilians cannot view this site for now';
	return;
    }

=cut

sub all_denied {
	my $self = shift;

	if((!defined($self->{_allowed_ips})) && !defined($self->{_deny_countries})) {
		return 0;
	}

	my $addr = $ENV{'REMOTE_ADDR'} ? $ENV{'REMOTE_ADDR'} : '127.0.0.1';

	if($self->{_allowed_ips}) {
		if($self->{_allowed_ips}->{$addr}) {
			return 0;
		}

		my @cidrlist;
		foreach my $block(keys(%{$self->{_allowed_ips}})) {
			@cidrlist = Net::CIDR::cidradd($block, @cidrlist);
		}
		if(Net::CIDR::cidrlookup($addr, @cidrlist)) {
			return 0;
		}
	}

	my %params;

	if(ref($_[0]) eq 'HASH') {
		%params = %{$_[0]};
	} elsif(@_ % 2 == 0) {
		%params = @_;
	} else {
		$params{'info'} = shift;
	}

	if((!defined($params{'info'})) && !defined($params{'lingua'})) {
		Carp::carp 'Usage: all_denied($info/$lingua)';
		return 1;
	}

	if(my $lingua = $params{'lingua'}) {
		return $self->{_deny_countries}->{$lingua->country()};
	}

	return 1;
}

=head1 AUTHOR

Nigel Horne, C<<  >>

=head1 BUGS

Please report any bugs or feature requests to C,
or through the web interface at
L.
I will be notified, and then you'll
automatically be notified of progress on your bug as I make changes.

=head1 SEE ALSO

L

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc CGI::ACL

You can also look for information at:

=over 4

=item * RT: CPAN's request tracker

L

=item * AnnoCPAN: Annotated CPAN documentation

L

=item * CPAN Ratings

L

=item * Search CPAN

L

=back

=head1 LICENSE AND COPYRIGHT

Copyright 2017 Nigel Horne.

This program is released under the following licence: GPL

=cut

1; # End of CGI::ACL