File Coverage

blib/lib/Business/RO/CIF.pm

Criterion	Covered	Total	%
statement	51	53	96.2
branch	12	14	85.7
condition	2	3	66.6
subroutine	8	8	100.0
pod	2	2	100.0
total	75	80	93.7

package Business::RO::CIF;
$Business::RO::CIF::VERSION = '0.004';
# ABSTRACT: Romanian CIF validation

use Moo;
use 5.010;
use utf8;
use Types::Standard qw(Int ArrayRef Str);

has 'cif' => (
    is       => 'ro',
    isa      => Str,
    required => 1,
);

has 'errstr' => (
    is       => 'rw',
    isa      => Str,
    default  => sub {''},
);

has 'rev_key' => (
    is       => 'lazy',
    isa      => ArrayRef,
    init_arg => undef,
);

sub _build_rev_key {
    my $self = shift;
    my @revkey = reverse split //, '753217532';
    return \@revkey;
}

has 'checksum' => (
    is       => 'rw',
    isa      => Int,
    init_arg => undef,
);

has 'rev_cif' => (
    is       => 'lazy',
    isa      => ArrayRef,
    init_arg => undef,
);

sub _build_rev_cif {
    my $self = shift;
    if ( my $cif = $self->cif ) {
        my @revcif = reverse split //, $cif;
        $self->checksum(shift @revcif);
        return \@revcif;
    }
    else {
        die "No CIF?";
    }
}

sub valid {
    my $self = shift;

    if ( $self->cif =~ m{[^0-9]} ) {
        $self->errstr('The input string contains invalid characters');
        return 0;
    }

    my @rev_cif = @{ $self->rev_cif };
    my @rev_key = @{ $self->rev_key };

    my $len = scalar @rev_cif;
    if ($len < 5) {
        $self->errstr('The input is too short (< 5)');
        return 0;
    }
    if ($len > 9) {
        $self->errstr('The input is too long (> 9)');
        return 0;
    }

    my $sum = 0;
    foreach ( 0 .. $#rev_cif ) {
        $sum += $rev_cif[$_] * $rev_key[$_];
    }

    my $m11 = $sum * 10 % 11;
    my $ctc = $m11 == 10 ? 0 : $m11;

    if ( $self->checksum == $ctc ) {
        return 1;
    }
    else {
        $self->errstr('The checksum failed');
        return 0;
    }
    return
}

sub BUILDARGS {
    my ( $class, @args ) = @_;
    if ( @args == 1 && !ref $args[0] ) {
        $args[0] =~ s{^RO\s*}{}i;
        return { cif => $args[0] };
    }
    else {
        my %para = @args;
        $para{cif} =~ s{^RO\s*}{}i;
        return \%para;
    }
}

1;

__END__