File Coverage

blib/lib/Business/PL/PESEL.pm

Criterion	Covered	Total	%
statement	51	61	83.6
branch	31	48	64.5
condition			n/a
subroutine	9	9	100.0
pod	5	5	100.0
total	96	123	78.0

# Copyright (C) 2012 by Tomasz Konojacki
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in
# all copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
# THE SOFTWARE.

package Business::PL::PESEL;

our $VERSION = '0.09';

use strict;
use warnings;
use utf8;

use Time::Piece;

sub new {
    my($class, %args) = @_;

    die 'PESEL number not specified in constructor' unless defined $args{-pesel};

    my $self = {
        %args
    };

    return bless $self, $class;
}

sub is_valid {
    my $self = shift;
    my %args = @_;

    my($checksum, $month, $range);

    return 0 unless defined $self->{-pesel};

    # Calculate checksum
    return 0 unless $self->{-pesel} =~ /^(\d)(\d)(\d)(\d)(\d)(\d)(\d)(\d)(\d)(\d)(\d)$/;
    $checksum = (1 * $1) + (3 * $2) + (7 * $3) + (9 * $4) + (1 * $5) + (3 * $6) + (7 * $7) + (9 * $8) + (1 * $9) + (3 * $10);
    $checksum %= 10;
    $checksum = 10 - $checksum unless $checksum == 0;
    return 0 unless ($11 == $checksum);

    unless ($args{-dont_check_date}) {
        # Check whether date is valid
        eval {
            $self->birth_date
        } or return 0;
    }

    # No errors, this is valid PESEL
    return 1;
}

sub is_male {
    my $self = shift;

    die 'PESEL number not specified' unless defined $self->{-pesel};
    die 'Invalid PESEL' unless $self->is_valid;
    die 'Invalid PESEL' unless $self->{-pesel} =~ /^\d{9}(\d)\d$/;

    return 0 if $1 % 2 == 0;
    return 1;
}

sub is_female {
    my $self = shift;

    die 'PESEL number not specified' unless defined $self->{-pesel};
    die 'Invalid PESEL' unless $self->is_valid;
    die 'Invalid PESEL' unless $self->{-pesel} =~ /^\d{9}(\d)\d$/;

    return 1 if $1 % 2 == 0;
    return 0;
}

sub birth_date {
    my $self = shift;

    my($year, $month, $day, $tp, $date);

    die 'PESEL number not specified' unless defined $self->{-pesel};
    die 'Invalid PESEL' unless $self->is_valid(-dont_check_date => 1) ;
    die 'Invalid PESEL' unless ($year, $month, $day) = $self->{-pesel} =~ /^(\d{2})(\d{2})(\d{2})\d{5}$/;

    if ($month - 80 > 0) {
        $month -= 80;
        $year = 18 . $year;
    }
    elsif ($month - 60 > 0) {
        $month -= 60;
        $year = 22 . $year;
    }
    elsif ($month - 40 > 0) {
        $month -= 40;
        $year = 21 . $year;
    }
    elsif ($month - 20 > 0) {
        $month -= 20;
        $year = 20 . $year;
    }
    else {
        $year = 19 . $year;
    }

    $date = "$day-$month-$year";

    eval {
        $tp = Time::Piece->strptime($date, '%d-%m-%Y');
    } or die 'Invalid PESEL: invalid date!';

    die 'Invalid PESEL: invalid date!' if ($date ne $tp->strftime('%d-%m-%Y'));

    return $tp;
}

1;

__END__