File Coverage

blib/lib/Bot/Cobalt/Plugin/Figlet.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Bot::Cobalt::Plugin::Figlet;
# ABSTRACT: Bot::Cobalt plugin for displaying figlets
$Bot::Cobalt::Plugin::Figlet::VERSION = '0.001';
use strict;
use warnings;

use Bot::Cobalt;
use Bot::Cobalt::Common;

use List::AllUtils qw(shuffle);
use Path::Tiny;
use Text::FIGlet;

sub new     { bless {}, shift }
sub fontdir { path( shift->{fontdir} )->absolute }
sub width   { shift->{maxwidth} }
sub prev    { shift->{previous} }

sub fonts {
   my $self  = shift;
   my $extrx = qr/\.[tf]lf$/;

   return map { $_->basename($extrx) } $self->fontdir->children($extrx);
}

sub Cobalt_register {
   my $self = shift;
   my $core = shift;
   my $conf = $core->get_plugin_cfg($self);

   $self->{fontdir}  = $conf->{fontdir}  || '/usr/games/lib/figlet';
   $self->{maxwidth} = $conf->{maxwidth} || -1;

   if (not -d $self->fontdir) {
      logger->warn("Unable to find figlet fonts at " . $self->fontdir);
      return PLUGIN_EAT_NONE;
   }

   register( $self, 'SERVER', 'public_cmd_figlet', 'public_cmd_prev_figlet' );

   logger->info("Registered, commands: !figlet, !prev_figlet");

   return PLUGIN_EAT_NONE;
}

sub Cobalt_unregister {
   my $self = shift;
   my $core = shift;

   logger->info("Unregistered");

   return PLUGIN_EAT_NONE;
}

sub Bot_public_cmd_prev_figlet {
   my $self = shift;
   my $core = shift;
   my $msg  = ${ shift() };

   broadcast( 'message', $msg->context, $msg->channel, $self->prev )
      if $self->prev;

   return PLUGIN_EAT_ALL;
}

sub Bot_public_cmd_figlet {
   my $self = shift;
   my $core = shift;

   my $msg     = ${ shift() };
   my $context = $msg->context;
   my $channel = $msg->target;
   my @split   = split(/ /, $msg->stripped);

   shift @split;

   my $str    = join(' ', @split);
   my $font   = (shuffle($self->fonts))[0];
   my $figlet = Text::FIGlet->new(-d => $self->fontdir, -f => $font);
   my $text   = $figlet->figify(-A => $str, -w => $self->width);

   $self->{previous} = $font;

   broadcast( 'message', $context, $channel, $_)
      foreach split /\n/, $text;

   return PLUGIN_EAT_ALL;
}

1;

__END__