File Coverage

blib/lib/Bot/Cobalt/Plugin/Bitly.pm

Criterion	Covered	Total	%
statement	7	9	77.7
branch			n/a
condition			n/a
subroutine	3	3	100.0
pod			n/a
total	10	12	83.3

package Bot::Cobalt::Plugin::Bitly;
# ABSTRACT: Bot::Cobalt plugin for auto-shortening URL via Bit.ly
$Bot::Cobalt::Plugin::Bitly::VERSION = '0.001';
use strict;
use warnings;

use Bot::Cobalt;
use Bot::Cobalt::Common;

use URI::Find::Simple;
use WebService::Bitly;

sub new        { bless {}, shift }
sub bitly      { shift->{bitly} }
sub min_length { shift->{min_length} }

sub Cobalt_register {
   my $self = shift;
   my $core = shift;
   my $cfg  = $core->get_plugin_cfg($self);

   $self->{min_length} = $cfg->{min_length} || 160;

   eval {
      $self->{bitly} = WebService::Bitly->new(%{$cfg->{creds}});
      register( $self, 'SERVER', 'public_msg' );
      logger->info("Registered");
   };

   if (my $err = $@) {
      logger->warn("Unable to create WebService::Bitly object: $err");
   }

   return PLUGIN_EAT_NONE;
}

sub Cobalt_unregister {
   my $self = shift;
   my $core = shift;

   logger->info("Unregistered");

   return PLUGIN_EAT_NONE;
}

sub Bot_public_msg {
   my $self = shift;
   my $core = shift;
   my $msg  = ${ shift() };

   my @url = grep {
      length($_) >= $self->min_length
   } ( URI::Find::Simple::list_uris( $msg->message ) );

   foreach my $url (@url) {
      my $short = $self->bitly->shorten($url);

      if ($short->is_error) {
         logger->warn("Bitly error: " . $short->status_txt);
         next;
      }

      broadcast( 'message', $msg->context, $msg->channel, $short->short_url );
   }

   return PLUGIN_EAT_NONE;
}

1;

__END__