File Coverage

blib/lib/Bot/Cobalt/IRC/Message/Public.pm

Criterion	Covered	Total	%
statement	32	33	96.9
branch	4	8	50.0
condition	3	7	42.8
subroutine	9	9	100.0
pod			n/a
total	48	57	84.2

package Bot::Cobalt::IRC::Message::Public;
$Bot::Cobalt::IRC::Message::Public::VERSION = '0.021003';
use v5.10;
use strictures 2;
use Scalar::Util 'blessed';

use Bot::Cobalt;
use Bot::Cobalt::Common;

require Bot::Cobalt::Core;

use Moo;
extends 'Bot::Cobalt::IRC::Message';

has cmd => (
  lazy      => 1,
  is        => 'rw',
  isa       => Any,
  predicate => 'has_cmd',
  builder   => '_build_cmd',
);

has highlight => (
  lazy      => 1,
  is        => 'rw',
  isa       => Bool,
  predicate => 'has_highlight',
  builder   => '_build_highlight',
);

has myself => (
  lazy      => 1,
  is        => 'rw',
  isa       => Str,
  builder   => sub {
    my ($self) = @_;
    my $irc;
    return ''
      unless Bot::Cobalt::Core->has_instance
      and $irc = irc_object($self->context);
    $irc->nick_name || ''
  },
);

after message => sub {
  my ($self, $value) = @_;
  return unless defined $value;

  if ($self->has_highlight) {
    $self->highlight( $self->_build_highlight );
  }

  if ($self->has_cmd) {
    $self->cmd( $self->_build_cmd );
  }
};

sub _build_highlight {
  my ($self) = @_;
  my $me  = $self->myself || return 0;
  my $txt = $self->stripped;
  $txt =~ /^${me}[,:;!-]?\s+/i
}

sub _build_cmd {
  my ($self) = @_;

  my $cmdchar = Bot::Cobalt::Core->has_instance ?
    (core->get_core_cfg->opts->{CmdChar} // '!') : '!'
  ;

  if ($self->stripped =~ /^${cmdchar}([^\s]+)/) {
    my $message = $self->message_array;
    shift @$message;
    # shift above modifies the ref, but intentionally hit trigger:
    $self->message_array($message);
    return lc($1)
  }
  undef
}


1;
__END__