File Coverage

blib/lib/Bot/Cobalt/IRC/Event/Nick.pm

Criterion	Covered	Total	%
statement	17	18	94.4
branch	1	2	50.0
condition	0	2	0.0
subroutine	5	5	100.0
pod	1	1	100.0
total	24	28	85.7

package Bot::Cobalt::IRC::Event::Nick;
$Bot::Cobalt::IRC::Event::Nick::VERSION = '0.021003';
use strictures 2;

use Bot::Cobalt::Common qw/:types/;
require Bot::Cobalt::Core;

use IRC::Utils qw/eq_irc/;

use Moo;
extends 'Bot::Cobalt::IRC::Event';

has old_nick => (
  lazy      => 1,
  is        => 'rw',
  isa       => Str,
  predicate => 'has_old_nick',
  default   => sub { $_[0]->src_nick },
);

has new_nick => (
  required  => 1,
  is        => 'rw',
  isa       => Str,
);

has channels => (
  required  => 1,
  is        => 'rw',
  isa       => ArrayObj,
  coerce    => 1,
  trigger   => sub {
    my ($self, $value) = @_;
    $self->_set_common($value) if $self->has_common;
  },
);

## ...just to remain compat with ::Quit:
has common   => (
  is        => 'ro',
  lazy      => 1,
  predicate => 'has_common',
  writer    => '_set_common',
  default   => sub { $_[0]->channels },
);

## Changing src on a Nick event makes no sense, as far as I can tell.
## ...but you can do it!
after 'src' => sub {
  my ($self) = @_;
  $self->old_nick( $self->src_nick ) if $self->has_old_nick;
};

sub equal {
  my ($self) = @_;

  my $casemap;
  if (Bot::Cobalt::Core->has_instance) {
    $casemap = core->get_irc_casemap($self->context) || 'rfc1459';
  } else {
    $casemap = 'rfc1459';
  }

  eq_irc($self->old_nick, $self->new_nick, $casemap)
}

1;
__END__