File Coverage

blib/lib/Bot/Cobalt/Core/Role/EasyAccessors.pm

Criterion	Covered	Total	%
statement	27	34	79.4
branch	5	14	35.7
condition	2	5	40.0
subroutine	7	8	87.5
pod	4	4	100.0
total	45	65	69.2

package Bot::Cobalt::Core::Role::EasyAccessors;
$Bot::Cobalt::Core::Role::EasyAccessors::VERSION = '0.021003';
use strictures 2;

use Scalar::Util 'blessed', 'reftype';
use Carp;

use Moo::Role;

requires qw/
  cfg
  PluginObjects
/;


sub get_channels_cfg {
  my ($self, $context) = @_;

  confess "get_channels_cfg expects a server context name"
    unless defined $context;

  ## Returns empty hash if there's no conf for this context
  my $chcfg = $self->cfg->channels->context($context) || {};

  for my $channel (keys %$chcfg) {
    ## Might be an empty string:
    $chcfg->{$channel} = +{}
      unless ref $chcfg->{$channel}
      and reftype $chcfg->{$channel} eq 'HASH'
  }

  $chcfg
}

sub get_core_cfg {
  my ($self) = @_;

  $self->cfg->core
}

sub get_plugin_alias {
  my ($self, $plugobj) = @_;
  confess "get_plugin_alias expects an object"
    unless blessed $plugobj;

  $self->PluginObjects->{$plugobj}
}

sub get_plugin_cfg {
  my ($self, $plugin) = @_;
  ## my $plugcf = $core->get_plugin_cfg( $self )

  confess "get_plugin_cfg expects a plugin alias or loaded object"
    unless defined $plugin;

  my $alias;

  if (blessed $plugin) {
    ## plugin obj specified
    unless ($alias = $self->PluginObjects->{$plugin}) {
      carp "get_plugin_cfg; No alias for $plugin";
      return
    }
  } else {
    ## string alias specified
    $alias = $plugin;
  }

  my $pcfg_obj = $self->cfg->plugins->plugin($alias);

  ## Return empty hash if this plugin has no config
  return {} unless blessed $pcfg_obj;

  ## Return opts() hash
  $pcfg_obj->opts
}


1;
__END__