File Coverage

blib/lib/Bot/Cobalt/Core/ContextMeta.pm

Criterion	Covered	Total	%
statement	38	40	95.0
branch	9	18	50.0
condition	5	14	35.7
subroutine	12	13	92.3
pod	7	7	100.0
total	71	92	77.1

package Bot::Cobalt::Core::ContextMeta;
$Bot::Cobalt::Core::ContextMeta::VERSION = '0.021003';
## Base class for context-specific dynamic hashes
## (ignores, auth, .. )

use strictures 2;
use Carp;

use Bot::Cobalt::Common ':types';

use Scalar::Util 'reftype';


use Moo;


has _list => (
  is        => 'rw',
  isa       => HashRef,
  builder   => sub { +{} },
);


sub add {
  my ($self, $context, $key, $meta) = @_;
  confess "add() needs at least a context and key"
    unless defined $context and defined $key;

  my $ref = +{ AddedAt => time };

  ## Allow AddedAt to be adjusted:
  if (ref $meta  && reftype $meta eq 'HASH') {
    $ref->{$_} = $meta->{$_} for keys %$meta;
  }

  $self->_list->{$context}->{$key} = $ref;

  $key
}

sub clear {
  my ($self, $context) = @_;

  $self->_list(+{}) unless defined $context;

  delete $self->_list->{$context}
}

sub del {
  my ($self, $context, $key) = @_;

  confess "del() needs a context and item"
    unless defined $context and defined $key;

  my $list = $self->_list->{$context} // return;

  delete $list->{$key}
}

sub fetch {
  my ($self, $context, $key) = @_;

  confess "fetch() needs a context and key"
    unless defined $context and defined $key;

  return unless exists $self->_list->{$context};

  $self->_list->{$context}->{$key}
}

sub list {
  my $self = shift;
  wantarray ? $self->list_as_array(@_) : $self->list_as_ref(@_)
}

## Less ambiguous list methods.

sub list_as_array { keys %{ shift->list_as_ref(@_) || +{} } }

sub list_as_ref {
  my ($self, $context) = @_;
  defined $context ? $self->_list->{$context} : $self->_list ;
}

1;
__END__