File Coverage

blib/lib/Bot/Cobalt/Core/ContextMeta/Auth.pm

Criterion	Covered	Total	%
statement	39	42	92.8
branch	8	18	44.4
condition	25	83	30.1
subroutine	13	14	92.8
pod	8	9	88.8
total	93	166	56.0

package Bot::Cobalt::Core::ContextMeta::Auth;
$Bot::Cobalt::Core::ContextMeta::Auth::VERSION = '0.021003';
use strictures 2;
use Carp;

use Bot::Cobalt::Common ':types';


use Moo;
extends 'Bot::Cobalt::Core::ContextMeta';


around add => sub {
  my ($orig, $self) = splice @_, 0, 2;
  ## auth->add(
  ##   Context  => $context,
  ##   Username => $username,
  ##   Host     => $host,
  ##   Level    => $level,
  ##   Flags    => $flags,
  ##   Alias    => $plugin_alias
  ## )
  my %args = @_;
  $args{lc $_} = delete $args{$_} for keys %args;

  for my $required (qw/context nickname username host level/) {
    unless (defined $args{$required}) {
      carp "add() missing mandatory opt $required";
      return
    }
  }

  $args{alias} = scalar caller unless defined $args{alias};
  $args{flags} = {}            unless defined $args{flags};

  my $meta = {
    Alias => $args{alias},
    Username => $args{username},
    Host  => $args{host},
    Level => $args{level},
    Flags => $args{flags},
  };

  $self->$orig($args{context}, $args{nickname}, $meta)
};

sub level {
  my ($self, $context, $nickname) = @_;

  return 0
    unless defined $context
    and defined $nickname
    and exists $self->_list->{$context}
    and ref $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Level} // 0
}

sub set_flag {
  my ($self, $context, $nickname, $flag) = @_;

  return
    unless defined $context
    and defined $nickname
    and $flag
    and exists $self->_list->{$context}
    and exists $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Flags}->{$flag} = 1
}

sub drop_flag {
  my ($self, $context, $nickname, $flag) = @_;

  return
    unless defined $context
    and defined $nickname
    and $flag
    and exists $self->_list->{$context}
    and exists $self->_list->{$context}->{$nickname};

  delete $self->_list->{$context}->{$nickname}->{Flags}->{$flag}
}

sub has_flag {
  my ($self, $context, $nickname, $flag) = @_;

  return
    unless defined $context
    and defined $nickname
    and $flag
    and exists $self->_list->{$context}
    and exists $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Flags}->{$flag}
}

sub flags {
  my ($self, $context, $nickname) = @_;

  return +{} unless exists $self->_list->{$context}
         and ref $self->_list->{$context}->{$nickname}
         and ref $self->_list->{$context}->{$nickname}->{Flags}
         and reftype $self->_list->{$context}->{$nickname}->{Flags} eq 'HASH';

  $self->_list->{$context}->{$nickname}->{Flags}
}

{ no warnings 'once'; *user = *username }
sub username {
  my ($self, $context, $nickname) = @_;

  return
    unless defined $context
    and defined $nickname
    and exists $self->_list->{$context}
    and ref $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Username}
}

sub host {
  my ($self, $context, $nickname) = @_;

  return
    unless defined $context
    and defined $nickname
    and exists $self->_list->{$context}
    and ref $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Host}
}

sub alias {
  my ($self, $context, $nickname) = @_;

  return
    unless defined $context
    and defined $nickname
    and exists $self->_list->{$context}
    and ref $self->_list->{$context}->{$nickname};

  $self->_list->{$context}->{$nickname}->{Alias}
}

sub move {
  my ($self, $context, $old, $new) = @_;
  ## User changed nicks, f.ex

  return unless exists $self->_list->{$context}->{$old};

  $self->_list->{$context}->{$new}
    = delete $self->_list->{$context}->{$old}
}


1;
__END__