File Coverage

blib/lib/Bot/Cobalt/Core/ContextMeta/Ignore.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch	2	4	50.0
condition	2	6	33.3
subroutine	7	7	100.0
pod	2	2	100.0
total	34	40	85.0

package Bot::Cobalt::Core::ContextMeta::Ignore;
$Bot::Cobalt::Core::ContextMeta::Ignore::VERSION = '0.021002';
use strictures 2;
use Carp;

use IRC::Utils 'normalize_mask';
use Bot::Cobalt::Common ':types';


use Moo;
extends 'Bot::Cobalt::Core::ContextMeta';


around add => sub {
  my $orig = shift;
  my ($self, $context, $mask, $reason, $addedby) = @_;

  my ($pkg, $line) = (caller)[0,2];

  confess "Missing arguments in ignore add()"
    unless defined $context and defined $mask;

  $mask    = normalize_mask($mask);
  $addedby = $pkg unless defined $addedby;
  $reason  = "Added by $pkg" unless defined $reason;

  my $meta = +{
    AddedBy => $addedby,
    Reason  => $reason,
  };

  $self->$orig($context, $mask, $meta)
};

sub reason {
  my ($self, $context, $mask) = @_;

  return unless exists $self->_list->{$context}
            and exists $self->_list->{$context}->{$mask};

  $self->_list->{$context}->{$mask}->{Reason}
}

sub addedby {
  my ($self, $context, $mask) = @_;

  return unless exists $self->_list->{$context}
            and exists $self->_list->{$context}->{$mask};

  $self->_list->{$context}->{$mask}->{AddedBy}
}

1;
__END__