File Coverage

blib/lib/Bit/FlipFlop.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	13	14	92.8
condition	8	15	53.3
subroutine	11	11	100.0
pod	7	7	100.0
total	74	82	90.2

package Bit::FlipFlop;

use strict;
#use warnings; # no warnings pragma - we'll try to be 5.005 compatible
use Carp;
$Bit::FlipFlop::VERSION = '0.01';

# this will hold the flip flops' guts,
# keyed by stringified object references
%Bit::FlipFlop::stash = ();

########################################
# Public methods
#
# read the pod for usage
#
# the rest of this is an obsfucated black box.  just kidding.

sub new {
  my $class = shift;
  my %args = @_;

  my $ff=0;
  my $f=bless \$ff, $class;

  $f->_init(%args);
  return $f;
}

sub test {
  my $f = shift;

  $Bit::FlipFlop::stash{"$f"}{ff} ||= $f->_build_ff;

  $$f = &{$Bit::FlipFlop::stash{"$f"}{ff}};
}

*Bit::FlipFlop::clock=\&test;

sub state {
  ${$_[0]}?1:0;
}

sub series {
 +${$_[0]};
}

sub lead_edge {
 ${$_[0]}==1?1:0;
}

sub trail_edge {
 ${$_[0]}=~/E/?1:0;
}

sub next_test {
 !${$_[0]}||$_[0]->trail_edge?'set':'reset';
}


########################################
# Private methods

sub _init {
  my $f = shift;
  my %args = @_;

  croak '"set" and "reset" coderef attributes are required.'
    unless defined($args{set}) and ref($args{set}) eq 'CODE'
       and defined($args{reset}) and ref($args{reset}) eq 'CODE';

  $args{simultaneous_edges} = 1
    unless defined $args{simultaneous_edges};

  @{$Bit::FlipFlop::stash{$f}}{qw/set reset dotdot/} =
    @args{qw/set reset simultaneous_edges/};
}

sub _build_ff {
  my $f = shift;

  my $op = $Bit::FlipFlop::stash{$f}{dotdot}?'..':'...';

  my $s = qq[
    sub {
     &{\$Bit::FlipFlop::stash{"$f"}{set}}
       $op
     &{\$Bit::FlipFlop::stash{"$f"}{reset}}
    }
  ];

# debug:
#  print $s;
  eval $s;
}
1;
__END__