File Coverage

blib/lib/Biblio/Zotero/DB.pm

Criterion	Covered	Total	%
statement	38	65	58.4
branch	2	12	16.6
condition			n/a
subroutine	14	22	63.6
pod	1	2	50.0
total	55	101	54.4

package Biblio::Zotero::DB;
# ABSTRACT: helper module to access the Zotero SQLite database
$Biblio::Zotero::DB::VERSION = '0.003';
use strict;
use warnings;

use v5.14;
use Moo;
use File::HomeDir;
use Path::Class;
use Path::Iterator::Rule;
use List::AllUtils qw(first);

use Biblio::Zotero::DB::Schema;
use Biblio::Zotero::DB::Library;


# used for L and L attr
my $make_directory_absolute = sub {
	my $orig = shift;
	my $self = $_[0];
	my $dir = $_[1];

	return $orig->($self, dir($dir)->absolute) if($dir);

	return $orig->(@_);
};

has schema => ( is => 'rw', builder => 1, lazy => 1, clearer => 1 );

sub _build_schema {
	my ($self) = @_;
	Biblio::Zotero::DB::Schema->connect('dbi:SQLite:dbname='.$self->db_file,
		'', '',
		{
			(zotero_storage_directory => $self->storage_directory)x!! $self->storage_directory
		},
	);
}

has db_file => ( is => 'rw', builder => 1, lazy => 1 );

sub _build_db_file {
	my ($self) = @_;
	dir($self->profile_directory)->file('zotero.sqlite');
}

has storage_directory => ( is => 'rw', builder => 1, lazy => 1 );

sub _build_storage_directory {
	my ($self) = @_;
	dir($self->profile_directory)->subdir('storage')->absolute if $self->profile_directory;
}

around storage_directory => $make_directory_absolute;

has profile_directory => ( is => 'rw' );

around profile_directory => $make_directory_absolute;

has profile_name => ( is => 'rw', trigger => 1, builder => 1, lazy => 1 );

sub _trigger_profile_name {
	my ($self) = @_;
	$self->profile_directory(
		first { dir($_)->components(-2) eq $self->profile_name }
			@{$self->find_profile_directories});
}

sub _build_profile_name {
	my ($self) = @_;
	dir($self->profile_directory)->components(-2) if $self->profile_directory;
}


# From
# Zotero for Firefox
#
# OS X                          /Users//Library/Application Support/Firefox/Profiles//zotero
# Windows 7/Vista               C:\Users\\AppData\Roaming\Mozilla\Firefox\Profiles\\zotero
# Windows XP/2000               C:\Documents and Settings\\Application Data\Mozilla\Firefox\Profiles\\zotero
# Linux (most distributions)    ~/.mozilla/firefox/Profiles//zotero
#
####
#
# Zotero Standalone
#
# OS X                          /Users//Library/Application Support/Zotero/Profiles//zotero
# Windows 7/Vista               C:\Users\\AppData\Roaming\Zotero\Profiles\\zotero
# Windows XP/2000               C:\Documents and Settings\\Application Data\Zotero\Profiles\\zotero
# Linux (most distributions)    ~/.zotero/Profiles//zotero


sub find_profile_directories {
	my ($self) = @_;
	for($^O) {
		return $self->_find_profile_directories_linux if($_ eq 'linux');
		return $self->_find_profile_directories_osx   if($_ eq 'darwin');
		return $self->_find_profile_directories_win   if($_ eq 'MSWin32');
		return [];
	}
}

sub _find_profile_directories_osx {
	my ($self) = @_;
	my $my_data = dir(File::HomeDir->my_data)->absolute;
	# gives /Users//Library/Application Support
	my $find = [
		dir($my_data, 'Firefox'),
		dir($my_data, 'Zotero') ];
	return $self->_find_profile_directories_under($find);
}

sub _find_profile_directories_win {
	my ($self) = @_;
	my $my_data = dir(File::HomeDir->my_data)->absolute;
	# gives C:\Users\\AppData\Local
	# or C:\Documents and Settings\\Local Settings\Application Data
	# depending on OS version
	if( $my_data->components(-1) eq "Local" ) {
		# for Windows 7 / Vista
		# this returns the \Local directory
		# we want the \Roaming directory that is on the same level
		$my_data = $my_data->parent->subdir('Roaming');
	}
	my $find = [
		dir( $my_data, 'Mozilla','Firefox'),
		dir( $my_data, 'Zotero') ];
	return $self->_find_profile_directories_under($find);
}

sub _find_profile_directories_linux {
	my ($self) = @_;
	my $find =  [
		dir(File::HomeDir->my_home , '.mozilla/firefox'),
		dir(File::HomeDir->my_home , '.zotero/zotero') ];
	return $self->_find_profile_directories_under($find);
}

sub _find_profile_directories_under {
	my ($self, $dirs) = @_;
	# finds either
	# dir('Profiles',,'zotero')
	# (actually, currently it doesn't check that it is indeed in the Profiles
	# directory)
	# or
	# dir(, 'zotero')
	return [ Path::Iterator::Rule->new
		->min_depth(1)->max_depth(3)
		->dir->name('zotero')->all( @$dirs ) ];
}

sub library {
	my $self = shift;
	return Biblio::Zotero::DB::Library->new( _db => $self );
}

1;

__END__