File Coverage

blib/lib/Biblio/SICI/ControlSegment.pm

Criterion	Covered	Total	%
statement	46	49	93.8
branch	7	10	70.0
condition	5	6	83.3
subroutine	12	12	100.0
pod	3	3	100.0
total	73	80	91.2

package Biblio::SICI::ControlSegment;
{
  $Biblio::SICI::ControlSegment::VERSION = '0.04';
}

# ABSTRACT: The control segment of a SICI

use strict;
use warnings;
use 5.010001;

use Moo;
use Sub::Quote;

use Biblio::SICI;
with 'Biblio::SICI::Role::ValidSegment', 'Biblio::SICI::Role::RecursiveLink';


has 'dpi' => (
	is        => 'rw', lazy => 1,
	trigger   => 1,
	default   => quote_sub(q{ 0 }),
	predicate => 1,
	clearer   => 1,
);

sub _trigger_dpi {
	my ( $self, $newVal ) = @_;

	if ( not( "$newVal" eq "0" or "$newVal" eq "1" or "$newVal" eq "2" or "$newVal" eq "3" ) ) {
		$self->log_problem_on( 'dpi' => ['value not in allowed range (0|1|2|3)'] );
	}
	else {
		$self->clear_problem_on('dpi');
	}

	return;
}


has 'mfi' => (
	is        => 'rw', lazy => 1,
	trigger   => 1,
	default   => quote_sub(q{ "ZU" }),
	predicate => 1,
	clearer   => 1,
);

sub _trigger_mfi {
	my ( $self, $newVal ) = @_;

	if ( $newVal !~ /\A(?:C[DFOT]|H[DE]|SC|T[BHLSX]|VX|Z[NUZ])\Z/ ) {
		$self->log_problem_on( 'mfi' => ['unknown identifier'] );
	}
	else {
		$self->clear_problem_on('mfi');
	}

	return;
}


has 'version' => (
	is        => 'rw', lazy => 1,
	trigger   => 1,
	default   => quote_sub(q{ 2 }),
	predicate => 1,
	clearer   => 1,
);

sub _trigger_version {
	my ( $self, $newVal ) = @_;

	if ( $newVal != 2 ) {
		$self->log_problem( 'version' => ['unsupported version number (i.e. not "2")'] );
	}
	else {
		$self->clear_problem_on('version');
	}

	return;
}


sub csi {
	my $self = shift;

	if ( $self->_sici()->contribution()->has_localNumber() ) {
		return 3;
	}

	if (   $self->_sici()->contribution()->has_location()
		or $self->_sici()->contribution()->has_titleCode() )
	{
		return 2;
	}

	return 1;
}


sub to_string {
	my $self = shift;

	# Every attribute in this class has a default value
	return sprintf( '%s.%s.%s;%s', $self->csi(), $self->dpi(), $self->mfi(), $self->version() );
}


sub reset {
	my $self = shift;
	$self->clear_dpi();
	$self->clear_problem_on('dpi');
	$self->clear_mfi();
	$self->clear_problem_on('mfi');
	$self->clear_version();
	$self->clear_problem_on('version');
	return;
}


1;

__END__