File Coverage

blib/lib/Biblio/SICI/ContributionSegment.pm

Criterion	Covered	Total	%
statement	55	60	91.6
branch	13	18	72.2
condition	2	3	66.6
subroutine	12	12	100.0
pod	2	2	100.0
total	84	95	88.4

package Biblio::SICI::ContributionSegment;
{
  $Biblio::SICI::ContributionSegment::VERSION = '0.04';
}

# ABSTRACT: The contribution segment of a SICI

use strict;
use warnings;
use 5.010001;

use Moo;
use Sub::Quote;

use Biblio::SICI;
with 'Biblio::SICI::Role::ValidSegment', 'Biblio::SICI::Role::RecursiveLink';

use Biblio::SICI::Util ();


has 'location' => ( is => 'rw', trigger => 1, predicate => 1, clearer => 1, );

sub _trigger_location {
	my ( $self, $newVal ) = @_;

	if ( $newVal !~ /\A${Biblio::SICI::Util::TITLE_CODE}+\Z/ ) {
		$self->log_problem_on( 'location' => ['contains invalid characters'] );
	}
	else {
		$self->clear_problem_on('location');
	}

	return;
}


has 'titleCode' => ( is => 'rw', trigger => 1, predicate => 1, clearer => 1, );

sub _trigger_titleCode {
	my ( $self, $newVal ) = @_;
	my @problems = ();

	if ( length $newVal > 6 ) {
		push @problems, 'contains more than 6 characters';
	}

	if ( $newVal !~ /\A${Biblio::SICI::Util::TITLE_CODE}+\Z/ ) {
		push @problems, 'contains invalid characters';
	}

	if (@problems) {
		$self->log_problem_on( titleCode => \@problems );
	}
	else {
		$self->clear_problem_on('titleCode');
	}

	return;
}


has 'localNumber' => ( is => 'rw', trigger => 1, predicate => 1, clearer => 1, );

sub _trigger_localNumber {
	my ( $self, $newVal ) = @_;

	if ( $newVal !~ /\A${Biblio::SICI::Util::TITLE_CODE}+\Z/ ) {
		$self->log_problem_on( 'location' => ['contains invalid characters'] );
	}
	else {
		$self->clear_problem_on('location');
	}

	return;
}


sub to_string {
	my $self = shift;
	my $str  = '';

	if ( $self->has_location() ) {
		$str .= $self->location();
	}

	if ( $self->has_titleCode() ) {
		$str .= ':' . $self->titleCode();
	}

	if ( $self->has_localNumber() ) {
		if ( $self->has_location() or $self->has_titleCode() ) {
			$str .= ':' . $self->localNumber();
		}
		else {
			$str .= '::' . $self->localNumber();
		}
	}

	return $str;
}


sub reset {
	my $self = shift;
	$self->clear_location();
	$self->clear_problem_on('location');
	$self->clear_titleCode();
	$self->clear_problem_on('titleCode');
	$self->clear_localNumber();
	$self->clear_problem_on('localNumber');

	return;
}


1;

__END__