File Coverage

blib/lib/Bash/Completion/Utils.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	17	18	94.4
condition	8	9	88.8
subroutine	9	9	100.0
pod	3	3	100.0
total	84	86	97.6

package Bash::Completion::Utils;
{
  $Bash::Completion::Utils::VERSION = '0.008';
}

# ABSTRACT: Set of utility functions that help writting plugins

use strict;
use warnings;
use parent 'Exporter';
use File::Spec::Functions;
use Config;

@Bash::Completion::Utils::EXPORT_OK = qw(
  command_in_path
  match_perl_modules
  prefix_match
);


sub command_in_path {
  my ($cmd) = @_;

  for my $path (grep {$_} split(/$Config{path_sep}/, $ENV{PATH})) {
    my $file = catfile($path, $cmd);
    return $file if -x $file;
  }

  return;
}



sub match_perl_modules {
  my ($pm) = @_;
  my ($filler, %found) = ('');

  $pm .= $filler = ':' if $pm =~ /[^:]:$/;

  my ($ns, $filter) = $pm =~ m{^(.+::)?(.*)};
  $ns = '' unless $ns;

  my $sdir = $ns;
  $sdir =~ s{::}{/}g;

  for my $lib (@INC) {
    next if $lib eq '.';
    _scan_dir_for_perl_modules(catdir($lib, $sdir), $ns, $filter, \%found);
  }

  my @found = keys %found;
  map {s/^$ns/$filler/} @found;

  return if 1 == @found && $found[0] eq $filter;    ## Exact match, ignore it
  return @found;
}

sub _scan_dir_for_perl_modules {
  my ($dir, $ns, $name, $found) = @_;

  return unless opendir(my $dh, $dir);

  while (my $entry = readdir($dh)) {
    next if $entry =~ /^[.]/;

    my $path = catfile($dir, $entry);

    if (-d $path && $entry =~ m/^$name/) {
      $found->{"$ns${entry}::"} = 1;
    }
    elsif (-f _ && $entry =~ m/^($name.*)[.]pm$/) {
      $found->{"$ns$1"} = 1;
    }
  }
}



sub prefix_match {
  my $prefix = shift;

  return grep {/^$prefix/} @_;
}

1;



=pod

=head1 NAME

Bash::Completion::Utils - Set of utility functions that help writting plugins

=head1 VERSION

version 0.008

=head1 SYNOPSIS

    use Bash::Completion::Utils qw(
      command_in_path match_perl_modules prefix_match
    );

    ...

=head1 DESCRIPTION

A library of utility functions usefull to plugin writers.

=head1 FUNCTIONS

=head2 command_in_path

Given a command name, returns the full path if we find it in the PATH.

=head2 match_perl_modules

Given a partial module name, returns a list of all the possible completions.

If a single exact match is found, it returns nothing.

Some examples:

=over 4

=item (empty string)

List all top level modules and namespaces.

=item Template

List C