File Coverage

lib/Badger/Codec/Chain.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	6	12	50.0
condition	1	3	33.3
subroutine	9	9	100.0
pod	6	6	100.0
total	64	72	88.8

#========================================================================
#
# Badger::Codec::Chain
#
# DESCRIPTION
#   Codec for encoding/decoding data via a chain of other codecs.
#
# AUTHOR
#   Andy Wardley
#
#========================================================================

package Badger::Codec::Chain;

use Badger::Codecs;
use Badger::Class
    version   => 0.01,
    debug     => 0,
    base      => 'Badger::Codec',
    constants => 'ARRAY',
    constant  => {
        CODECS  => 'Badger::Codecs',
        CHAIN   => __PACKAGE__,
        CHAINED => qr/\s*\+\s*/,
    },
    exports   => {
        any   => 'CHAIN CHAINED'
    };


sub new {
    my $class = shift;
    my $chain = @_ == 1 ? shift : [ @_ ];

    # single argument can be a text string or array ref
    # each argument in an array can be a codec ref or codec name/chain
    # all codec names must be upgraded to codec objects
    $chain = [ $chain ] unless ref $chain eq ARRAY;
    $chain = [ map { ref $_ ? $_ : split(CHAINED, $_) } @$chain ];
    $chain = [ map { ref $_ ? $_ : CODECS->codec($_)  } @$chain ];

    $class->debug("chaining codecs: ", join(' + ', @$chain), "\n") if $DEBUG;

    bless {
        chain => $chain,
    }, $class;
}

sub encode {
    my $self = shift;
    my $data = shift;
    foreach my $codec (@{ $self->{ chain } }) {
        $data = $codec->encode($data);
    }
    return $data;
}

sub decode {
    my $self = shift;
    my $data = shift;
    foreach my $codec (reverse @{ $self->{ chain } }) {
        $data = $codec->decode($data);
    }
    return $data;
}

sub encoder {
    my $self = shift;
    return $self->coder(
        map { $_->encoder }
        @{ $self->{ chain } }
    );
}

sub decoder {
    my $self = shift;
    return $self->coder(
        reverse map { $_->decoder }
        @{ $self->{ chain } }
    );
}

sub coder {
    my $self   = shift;
    my $coders = @_ && ref $_[0] eq ARRAY ? shift : [@_];
    return sub {
        my $data = shift;
        foreach my $coder (@$coders) {
            $data = $coder->($data);
        }
        return $data;
    }
}

1;

__END__