File Coverage

blib/lib/Parse/BACKPAN/Packages.pm

Criterion	Covered	Total	%
statement	34	48	70.8
branch	5	10	50.0
condition			n/a
subroutine	10	13	76.9
pod	8	8	100.0
total	57	79	72.1

package Parse::BACKPAN::Packages;

use strict;
use warnings;

our $VERSION = '0.40';

use Mouse;
use BackPAN::Index::Types;

has no_cache =>
  is		=> 'ro',
  isa		=> 'Bool',
  default 	=> 0;

has only_authors =>
  is		=> 'ro',
  isa		=> 'Bool',
  default	=> 1
;

has _delegate =>
  is	=> 'rw',
  isa	=> 'BackPAN::Index';


sub BUILD {
    my $self = shift;
    my $args = shift;

    # Translate from PBP options to BackPAN::Index
    if( exists $args->{no_cache} ) {
	$args->{update} = $args->{no_cache};
    }

    if( exists $args->{only_authors} ) {
	$args->{releases_only_from_authors} = $args->{only_authors};
    }

    require BackPAN::Index;
    $self->_delegate( BackPAN::Index->new($args) );

    return $self;
}

our $AUTOLOAD;
sub AUTOLOAD {
    my $self = shift;
    my($method) = $AUTOLOAD =~ /:: ([^:]+) $/x;

    # Skip things like DESTROY
    return if uc $method eq $method;

    $self->_delegate->$method(@_);
}

sub files {
    my $self = shift;

    my %files;
    my $rs = $self->_delegate->files;
    while( my $file = $rs->next ) {
        $files{$file->path} = $file;
    }

    return \%files;
}

sub file {
    my ( $self, $path ) = @_;

    return $self->_delegate->files->single({ path => $path });
}

sub releases {
    my($self, $dist) = @_;

    return $self->_delegate->releases($dist)->all;
}


sub distributions {
    my $self = shift;

    # For backwards compatibilty when releases() was distributions()
    return $self->releases(shift) if @_;

    return [$self->_delegate->distributions->get_column("name")->all];
}

sub distributions_by {
    my ( $self, $author ) = @_;
    return unless $author;

    my $dists = $self->db->dbh->selectcol_arrayref(q[
             SELECT DISTINCT dist
             FROM   releases
             WHERE  cpanid = ?
             ORDER BY dist
        ],
        undef,
        $author
    );

    return @$dists;
}

sub authors {
    my $self     = shift;

    my $authors = $self->db->dbh->selectcol_arrayref(q[
        SELECT DISTINCT cpanid
        FROM     releases
        ORDER BY cpanid
    ]);

    return @$authors;
}

sub size {
    my $self = shift;

    my $size = $self->db->dbh->selectcol_arrayref(q[
        SELECT SUM(size) FROM files
    ]);

    return $size->[0];
}

1;

__END__