File Coverage

blib/lib/Babble/Plugin/State.pm

Criterion	Covered	Total	%
statement	29	31	93.5
branch	7	8	87.5
condition			n/a
subroutine	3	4	75.0
pod	0	2	0.0
total	39	45	86.6

package Babble::Plugin::State;

use Moo;

sub transform_to_plain {
  my ($self, $top) = @_;
  $top->remove_use_argument(feature => 'state');
  my $make_tf = sub { my ($lead) = @_; sub {
    my ($m) = @_;
    my @states;
    my @gensym;
    $m->each_match_within(Assignment => [
      'state \b (?>(?&PerlOWS))',
      [ type => '(?: (?&PerlQualifiedIdentifier) (?&PerlOWS) )?+' ],
      [ declares => '(?>(?&PerlLvalue))' ],
      '(?>(?&PerlOWS))',
      [ attributes => '(?&PerlAttributes)?+' ],
      '(?: (?>(?&PerlOWS)) = (?>(?&PerlOWS))',
        [ assigns => '(?&PerlConditionalExpression)' ],
      ')*+',
    ] => sub {
      my ($m) = @_;
      my $st = $m->subtexts;
      push @states, $st;
      if (my $assigns = $st->{assigns}) {
        my $genlex = '$'.$m->gensym;
        my $text = '('
          .$genlex
          .' ? '.$st->{declares}
          .' : ++'.$genlex.' and '.$st->{declares}.' = '.$assigns
          .')';
        push @gensym, $genlex;
        $m->replace_text($text);
        return;
      }
      $m->replace_text('do { no warnings qw(void); '.$st->{declares}.' }');
    });
    if (@states) {
      my $state_statements = join ' ',
         (@gensym ? 'my ('.join(', ', @gensym).');' : ()),
         (map {
           'my '.$_->{type}.$_->{declares}
           .($_->{attributes} ? ' '.$_->{attributes} : '')
           .';'
         } @states);
      $m->transform_text(sub {
        s/\A/${lead}{ ${state_statements} /;
        s/\Z/ }/;
      });
    }
  } };
  $top->each_match_of(AnonymousSubroutine => $make_tf->('do '));
  $top->each_match_of(SubroutineDeclaration => $make_tf->(''));
}

sub check_bail_out_early {
  my ($self, $top) = @_;
  $top->text !~ m/ \b state \b /xs;
}

1;
__END__

=head1 NAME

Babble::Plugin::State - Plugin for state keyword

=head1 SYNOPSIS

Converts usage of C<state> variable to C<my>.

=head1 SEE ALSO

L<state feature|feature/"The 'state' feature">

=cut