File Coverage

blib/lib/Aspect/Library/Timer.pm

Criterion	Covered	Total	%
statement	42	44	95.4
branch	5	6	83.3
condition			n/a
subroutine	9	10	90.0
pod	0	2	0.0
total	56	62	90.3

package Aspect::Library::Timer;

use 5.008002;
use strict;
use warnings;
use Aspect::Modular 1.00 ();
use Time::HiRes   1.9718 ();

use vars qw{$VERSION @ISA};
BEGIN {
	$VERSION = '1.10';
	@ISA     = 'Aspect::Modular';
}

sub get_advice {
	my $self     = shift;
	my $pointcut = shift;
	my $handler  = @_ ? shift : \&handler;
	my $DISABLE  = 0;
	Aspect::Advice::Around->new(
		lexical  => $self->lexical,
		pointcut => $pointcut,
		code     => sub {
			# Prevent recursion in the report handler
			if ( $DISABLE ) {
				$_->proceed;
				return;
			}

			# Capture the time
			my $error = '';
			SCOPE: {
				local $@;
				my @start = Time::HiRes::gettimeofday();
				eval {
					$_->proceed;
				};
				$error = $@;
				my @stop  = Time::HiRes::gettimeofday();

				# Process the time
				$DISABLE++;
				eval {
					$handler->(
						$_->sub_name,
						\@start,
						\@stop,
						Time::HiRes::tv_interval(
							\@start,
							\@stop,
						)
					);
				};
				$DISABLE--;
			}

			die $error if $error;
			return;
		},
	);
}

sub handler {
	my ( $name, $start, $stop, $interval ) = @_;
	printf STDERR "%s - %s\n", $interval, $name;
}

1;

__END__