File Coverage

blib/lib/Ask/API.pm

Criterion	Covered	Total	%
statement	42	76	55.2
branch	9	18	50.0
condition	3	12	25.0
subroutine	10	14	71.4
pod	0	8	0.0
total	64	128	50.0

use 5.008008;
use strict;
use warnings;

package Ask::API;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.013';

use Moo::Role;
use Path::Tiny 'path';

requires 'entry';    # get a string of text
requires 'info';     # display a string of text

sub _lang_support {
	my $self = shift;
	require Lingua::Boolean::Tiny;
	"Lingua::Boolean::Tiny"->new( @_ );
}

sub is_usable {
	my ( $self ) = @_;
	return 1;
}

sub quality {
	return 50;
}

sub warning {
	my ( $self, %o ) = @_;
	$o{text} = "WARNING: $o{text}";
	return $self->info( %o );
}

sub error {
	my ( $self, %o ) = @_;
	$o{text} = "ERROR: $o{text}";
	return $self->info( %o );
}

sub question {
	my ( $self, %o ) = @_;

	my $response = $self->entry( text => $o{text} );
	my $lang     = $self->_lang_support( $o{lang} );
	$lang->boolean( $response );
}

sub file_selection {
	my ( $self, %opts ) = ( shift, @_ );

	$opts{text} ||= 'Enter file name';

	my @chosen;

	FILE: {
		my $got = $self->entry( text => $opts{text} );

		if ( not length $got ) {
			last FILE if $opts{multiple};
			redo FILE;
		}

		$got = path $got;

		if ( $opts{existing} and not $got->exists ) {
			$self->error( text => 'Does not exist.' );
			redo FILE;
		}

		if ( $opts{directory} and not $got->is_dir ) {
			$self->error( text => 'Is not a directory.' );
			redo FILE;
		}

		push @chosen, $got;

		if ( $opts{multiple} ) {
			$self->info( text => 'Enter another file, or leave blank to finish.' );
			redo FILE;
		}
	} #/ FILE:

	$opts{multiple} ? @chosen : $chosen[0];
} #/ sub file_selection

my $format_choices = sub {
	my ( $self, $choices ) = @_;
	join q[, ], map { sprintf( '"%s" (%s)', @$_ ) } @$choices;
};

my $filter_chosen = sub {
	my ( $self, $choices, $response ) = @_;
	my $valid = {};
	$valid->{ $_->[0] }++ for @$choices;
	my @choices = ( $response =~ /\w+/g );
	return (
		[ grep $valid->{$_},  @choices ],
		[ grep !$valid->{$_}, @choices ],
	);
};

sub multiple_choice {
	my ( $self, %o ) = @_;
	my $choices = $self->$format_choices( $o{choices} );

	my ( $allowed, $disallowed, $repeat );

	for ( ; ; ) {
		my $response = $self->entry(
			text =>
				"$o{text}. Choices: $choices. (Separate multiple choices with white space.)",
			entry_text => $repeat || '',
		);
		( $allowed, $disallowed ) = $self->$filter_chosen( $o{choices}, $response );
		if ( @$disallowed ) {
			my $d = join q[, ], @$disallowed;
			$self->error(
				text => "Not valid: $d. Please try again.",
			);
			$repeat = join q[ ], @$allowed;
		}
		else {
			last;
		}
	} #/ for ( ; ; )

	return @$allowed;
} #/ sub multiple_choice

sub single_choice {
	my ( $self, %o ) = @_;
	my $choices = $self->$format_choices( $o{choices} );

	my ( $allowed, $disallowed, $repeat );

	for ( ; ; ) {
		my $response = $self->entry(
			text       => "$o{text}. Choices: $choices. (Choose one.)",
			entry_text => $repeat || '',
		);
		( $allowed, $disallowed ) = $self->$filter_chosen( $o{choices}, $response );
		if ( @$disallowed ) {
			my $d = join q[, ], @$disallowed;
			$self->error(
				text => "Not valid: $d. Please try again.",
			);
			$repeat = $allowed->[0];
		}
		elsif ( @$allowed != 1 ) {
			$self->error(
				text => "Not valid: choose one.",
			);
			$repeat = $allowed->[0];
		}
		else {
			last;
		}
	} #/ for ( ; ; )

	return $allowed->[0];
} #/ sub single_choice

1;

__END__