File Coverage

blib/lib/Array/PrintCols/EastAsian.pm

Criterion	Covered	Total	%
statement	114	116	98.2
branch	34	36	94.4
condition	13	15	86.6
subroutine	17	17	100.0
pod	3	3	100.0
total	181	187	96.7

package Array::PrintCols::EastAsian;
use 5.010;
use strict;
use warnings;
use utf8;

use Carp;
use Encode;
use Data::Validator;
use Term::ReadKey;
use Text::VisualWidth::PP;
$Text::VisualWidth::PP::EastAsian = 1;
use parent qw/ Exporter /;

our $VERSION = '0.07';

our @EXPORT    = qw/ format_cols print_cols pretty_print_cols /;
our @EXPORT_OK = qw/ _max _min _validate _align /;

sub _max {
    my @array = @_;
    my $max   = shift @array;
    foreach (@array) {
        if ( $max < $_ ) { $max = $_; }
    }
    return $max;
}

sub _min {
    my @array = @_;
    my $min   = shift @array;
    foreach (@array) {
        if ( $min > $_ ) { $min = $_; }
    }
    return $min;
}

sub _validate {
    my ( $array, $options ) = @_;
    if ( !defined $options ) { $options = {}; }
    state $rules = Data::Validator->new(
        array  => { isa => 'ArrayRef' },
        gap    => { isa => 'Int', default => 0 },
        column => { isa => 'Int', optional => 1 },
        width  => { isa => 'Int', optional => 1 },
        align  => { isa => 'Str', default => 'left' },
        encode => { isa => 'Str', default => 'utf-8' },
    )->with('Sequenced');
    my $args = $rules->validate( $array, $options );
    if ( $args->{gap} < 0 ) { croak 'Gap option should be a integer greater than or equal 1.'; }
    if ( exists $args->{column} && $args->{column} <= 0 ) { croak 'Column option should be a integer greater than 0.'; }
    if ( exists $args->{width}  && $args->{width} <= 0 )  { croak 'Width option should be a integer greater than 0.'; }
    if ( !( $args->{align} =~ m/^(left|center|right)$/i ) ) {
        croak 'Align option should be left, center, or right.';
    }
    return $args;
}

sub _align {
    my $args    = shift;
    my @length  = map { Text::VisualWidth::PP::width $_ } @{ $args->{array} };
    my $max_len = _max(@length);
    my ( @formatted_array, $space );
    for ( 0 .. $#{ $args->{array} } ) {
        $space = $max_len - $length[$_];
        if ( $args->{align} =~ m/^left$/i )  { push @formatted_array, $args->{array}->[$_] . q{ } x $space; }
        if ( $args->{align} =~ m/^right$/i ) { push @formatted_array, q{ } x $space . $args->{array}->[$_]; }
        if ( $args->{align} =~ m/^center$/i ) {
            my $half_space = int $space / 2;
            push @formatted_array, q{ } x $half_space . $args->{array}->[$_] . q{ } x ( $space - $half_space );
        }
    }
    return \@formatted_array;
}

sub format_cols {
    my ( $array, $options ) = @_;
    my $args = _validate( $array, $options );
    return _align($args);
}

sub print_cols {
    my ( $array, $options ) = @_;
    my $args            = _validate( $array, $options );
    my $formatted_array = _align($args);
    my $gap             = $args->{gap};
    my $encode          = $args->{encode};
    my $column;
    if ( exists $args->{column} ) { $column = $args->{column}; }
    if ( exists $args->{width} ) {
        my $element_width = Text::VisualWidth::PP::width $formatted_array->[0];
        $column = _max( 1, int 1 + ( $args->{width} - $element_width ) / ( $element_width + $gap ) );
        if ( exists $args->{column} ) { $column = _min( $args->{column}, $column ); }
    }
    if ( !$column ) { $column = $#{$formatted_array} + 1; }

    my ( $str, $encoded_str ) = q{};
    for ( 0 .. $#{$formatted_array} ) {
        if ( $_ % $column ) {
            $str = $str . q{ } x $gap;
        }
        else {
            if ($str) { $str = $str . "\n"; }
        }
        $str = $str . $formatted_array->[$_];
    }
    $str = $str . "\n";
    $encoded_str = encode $encode, $str;
    print $encoded_str;
    return;
}

sub pretty_print_cols {
    my ( $array, $options ) = @_;
    my $gap    = $options->{gap}    // 1;
    my $align  = $options->{align}  // 'left';
    my $encode = $options->{encode} // 'utf-8';
    my $terminal_width;
    if ( $^O =~ /Win32/i ) {
        $terminal_width = ( GetTerminalSize  )[0];
    }
    else {
        $terminal_width = (GetTerminalSize)[0];
    }
    if ( $terminal_width =~ /^\d+$/ && $terminal_width != 0 ) {
        print_cols( $array, { 'gap' => $gap, 'width' => $terminal_width, 'align' => $align, 'encode' => $encode } );
    }
    else {
        print_cols( $array, { 'gap' => $gap, 'align' => $align, 'encode' => $encode } );
    }
    return;
}

1;
__END__