File Coverage

blib/lib/Array/OverlapFinder.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	10	10	100.0
condition	3	3	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	65	65	100.0

package Array::OverlapFinder;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-12-25'; # DATE
our $DIST = 'Array-OverlapFinder'; # DIST
our $VERSION = '0.002'; # VERSION

use 5.010001;
use strict;
use warnings;

use Exporter qw(import);
our @EXPORT_OK = qw(find_overlap combine_overlap);

sub _find_or_combine_overlap {
    my ($action, $seq1, $seq2, $detail) = @_;

    my @overlap_items;
    my $index_at_seq1;

  L1:
    for my $i (0 .. $#{$seq1}) {
        my $j = $i;
        while ($j <= $#{$seq1} && ($j-$i) <= $#{$seq2}) {
            if ($seq1->[$j] ne $seq2->[$j - $i]) {
                next L1;
            }
            $j++;
        }
        @overlap_items = @{$seq1}[$i .. $#{$seq1}];
        $index_at_seq1 = $i;
        last L1;
    }

    if ($action eq 'find') {
        # find
        if ($detail) { return (\@overlap_items, $index_at_seq1) } else { return @overlap_items }
    } else {
        # combine
        my @combined;
        if (defined $index_at_seq1) {
            @combined = (@$seq1, @{$seq2}[ ($#{$seq1} - $index_at_seq1 + 1) .. $#{$seq2} ]);
        } else {
            @combined = (@$seq1, @$seq2);
        }
        if ($detail) { return (\@combined, \@overlap_items, $index_at_seq1) } else { return @combined }
    }
}

sub find_overlap    { _find_or_combine_overlap('find', @_) }

sub combine_overlap { _find_or_combine_overlap('combine', @_) }

1;
# ABSTRACT: Find/remove overlapping items between two ordered sequences

__END__