File Coverage

blib/lib/Archive/TAP/Convert.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	5	10	50.0
condition			n/a
subroutine	9	9	100.0
pod	1	1	100.0
total	52	59	88.1

# ABSTRACT: Read from a TAP archive and convert it for displaying

package Archive::TAP::Convert;
{
  $Archive::TAP::Convert::VERSION = '0.006';
}

use strict;
use warnings;

use Capture::Tiny qw( capture_merged );
use TAP::Harness;
use TAP::Harness::Archive;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(convert_from_taparchive);

# one and only subroutine of this module
sub convert_from_taparchive {

    my %args = @_;

    # Input Arguments: archive, formatter, force_inline
    # Set default values:
    die 'no archive specified'
        unless (exists $args{archive});
    $args{formatter} = 'TAP::Formatter::HTML'
        unless (exists $args{formatter});
    $args{force_inline} = 0
        unless (exists $args{force_inline});

    # This is the complicate but flexible version to:
    #   use TAP::Formatter::HTML;
    #   my $formatter = TAP::Formatter::HTML->new;
    my $formatter;
    (my $require_name = $args{formatter} . ".pm") =~ s{::}{/}g;
    eval {
        require $require_name;
        $formatter = $args{formatter}->new();
    };
    die "Problems with formatter $args{formatter}"
      . " at $require_name: $@"
        if $@;

    # if set, include all CSS and JS in HTML file
    if ($args{force_inline}) {
        $formatter->force_inline_css(1);
        $formatter->force_inline_js (1);
    }

    # Now we do a lot of magic to convert this stuff...

    my $harness = TAP::Harness->new({ formatter => $formatter });

    $formatter->really_quiet(1);
    $formatter->prepare;

    my $session;
    my $aggregator = TAP::Harness::Archive->aggregator_from_archive({
        archive          => $args{archive},
        parser_callbacks => {
            ALL => sub {
                $session->result( $_[0] );
            },
        },
        made_parser_callback => sub {
            $session = $formatter->open_test( $_[1], $_[0] );
        }
    });

    $aggregator->start;
    $aggregator->stop;

    # This code also prints to STDOUT but we will catch it!
    return capture_merged { $formatter->summary($aggregator) };

}

1;

__END__