File Coverage

blib/lib/ArangoDB2/User.pm

Criterion	Covered	Total	%
statement	15	43	34.8
branch	0	10	0.0
condition			n/a
subroutine	5	14	35.7
pod	9	9	100.0
total	29	76	38.1

package ArangoDB2::User;

use strict;
use warnings;

use base qw(
    ArangoDB2::Base
);

use Data::Dumper;
use JSON::XS;

my $JSON = JSON::XS->new->utf8;

my @PARAMS = qw(
    active changePassword extra name passwd
);



###############
# API METHODS #
###############

# create
#
# POST /_api/user
sub create
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, \@PARAMS);
    # use name for user param
    $args->{user} = delete $args->{name};
    # make request
    my $res = $self->arango->http->post(
        $self->api_path('user'),
        undef,
        $JSON->encode($args),
    ) or return;
    # if request was success copy args to self
    $self->_build_self($res, \@PARAMS);

    return $self;
}

# delete
#
# DELETE /_api/user/{user}
sub delete
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, ['name']);
    # make request
    return $self->arango->http->delete(
        $self->api_path('user', delete $args->{name}),
    ) or return;
}

# get
#
# GET /_api/user/{user}
sub get
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, ['name']);
    # make request
    my $res = $self->arango->http->get(
        $self->api_path('user', delete $args->{name}),
    ) or return;
    # copy param data from res to self
    $self->_build_self($res, \@PARAMS);

    return $self;
}

# patch
#
# PATCH /_api/user/{user}
sub patch
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, \@PARAMS);
    # make request
    my $res = $self->arango->http->patch(
        $self->api_path('user', delete $args->{name}),
        undef,
        $JSON->encode($args),
    ) or return;
    # if request was success copy args to self
    $self->_build_self($res, \@PARAMS);

    return $self;
}

# replace
#
# PUT /_api/user/{user}
sub replace
{
    my($self, $args) = @_;
    # process request args
    $args = $self->_build_args($args, \@PARAMS);
    # make request
    my $res = $self->arango->http->put(
        $self->api_path('user', delete $args->{name}),
        undef,
        $JSON->encode($args),
    ) or return;
    # if request was success copy args to self
    $self->_build_self($res, \@PARAMS);

    return $self;
}

####################
# PROPERTY METHODS #
####################

sub active { shift->_get_set_bool('active', @_) }

sub changePassword  { shift->_get_set_bool('changePassword', @_) }

sub extra { shift->_get_set('extra', @_) }

sub passwd { shift->_get_set('passwd', @_) }

1;

__END__