File Coverage

script/docsiscious

Criterion	Covered	Total	%
statement	25	25	100.0
branch			n/a
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	34	34	100.0

#!/usr/bin/env perl
use Mojolicious::Lite;
use Mojo::Util 'steady_time';
use DOCSIS::ConfigFile qw( decode_docsis encode_docsis );
use File::Basename;
use File::Spec::Functions qw( catdir catfile );
use FindBin;
use YAML::XS;
BEGIN { unshift @INC, "$FindBin::Bin/../lib" }
use App::docsisicious;

my $STORAGE = $ENV{DOCSIS_STORAGE} || ($ENV{HOME} ? catdir $ENV{HOME}, '.docsisicious' : '');
die "DOCSIS_STORAGE=/path/to/docsis/files need to be set" unless $STORAGE;
mkdir $STORAGE or die "mkdir $STORAGE: $!" unless -d $STORAGE;
app->log->info("Will store DOCSIS config files in $STORAGE");

get '/' => {layout => 'default'} => 'editor';
get '/css/docsis/:version' => [format => ['css']] => {template => 'css/docsis'};
get '/js/docsis/:version'  => [format => ['js']]  => {template => 'js/docsis'};

my $download = sub {
  my $c = shift;

  eval {
    my $config = YAML::XS::Load($c->param('config'));
    delete $config->{$_} for qw( CmMic CmtsMic );
    my $binary = encode_docsis $config, {shared_secret => $c->param('shared_secret')};
    my $filename = $c->param('filename') || $config->{filename} || sprintf '%s.bin', $c->paste_id;
    $filename =~ s![^\w\.-]!-!g;
    $c->res->headers->content_disposition("attachment; filename=$filename");
    $c->render(data => $binary, format => 'binary');
  } or do {
    my $err = $@;
    chomp $err;
    $c->app->log->warn("Could not encode_docsis: $err");
    $err =~ s! at \S+.*$!!s;
    $c->render(error => "Cannot encode config file: $err", status => 400);
  };
};

my $save = sub {
  my $c      = shift;
  my $id     = $c->paste_id;
  my $config = $c->param('config');
  my %data;

  eval {
    die 'Empty config' unless length $config;
    $data{filename}      = $c->param('filename');
    $data{shared_secret} = $c->param('shared_secret');
    $data{ts}            = Mojo::Date->new->to_datetime;
    $data{config}        = YAML::XS::Load($config);
    Mojo::Util::spurt(YAML::XS::Dump(\%data), catfile $STORAGE, "$id.yaml");
    $c->redirect_to('edit' => id => $id);
  } or do {
    my $err = $@;
    chomp $err;
    $err =~ s! at \S+.*$!!s;
    $c->render(error => "Cannot encode config file: $err", status => 400);
  };
};

my $upload = sub {
  my $c      = shift;
  my $binary = $c->req->upload('binary');

  eval {
    my $config = decode_docsis $binary->slurp;
    $c->param(config   => YAML::XS::Dump($config));
    $c->param(filename => basename $binary->filename);
  } or do {
    my $err = $@;
    chomp $err;
    $err =~ s! at \S+.*$!!s;
    $c->render(error => "Cannot decode config file: $err", status => 400);
  };
};

get(
  '/edit/example' => {layout => 'default', template => 'editor'} => sub {
    my $c = shift;
    $c->param(config => Mojo::Loader::data_section(__PACKAGE__, 'example.yaml'));
    $c->param(filename => 'example.bin');
  },
  'example',
);

get(
  '/edit/:id' => {layout => 'default', template => 'editor'} => sub {
    my $c    = shift;
    my $id   = $c->paste_id;
    my $data = YAML::XS::Load(Mojo::Util::slurp(catfile $STORAGE, "$id.yaml"));
    $c->param(config        => YAML::XS::Dump($data->{config}));
    $c->param(filename      => $data->{filename});
    $c->param(shared_secret => $data->{shared_secret});
  },
  'edit'
);

post(
  '/' => {layout => 'default', template => 'editor'} => sub {
    my $c = shift;
    return $c->$save     if $c->param('save');
    return $c->$download if $c->param('download');
    return $c->$upload   if $c->req->upload('binary');
    return $c->render(text => "Either download, binary or save need to be present.\n", status => 400);
  },
  'save'
);

helper paste_id => sub {
  my $c = shift;
  my $id = $c->param('id') || Mojo::Util::md5_sum($^T . $$ . steady_time);
  die "Invalid id: $id" unless $id =~ /^\w+$/;
  die "Invalid id: $id" if $id eq 'example';
  return $id;
};

app->home->parse(App::docsisicious->HOME);
app->static->paths([app->home->rel_dir('public')]);
app->defaults(error => '', VERSION => App::docsisicious->VERSION);
app->defaults->{VERSION} =~ s!\W+!-!g;
app->start;

__DATA__