File Coverage

blib/lib/App/diceware.pm

Criterion	Covered	Total	%
statement	67	67	100.0
branch	4	6	66.6
condition	6	6	100.0
subroutine	17	17	100.0
pod	0	2	0.0
total	94	98	95.9

package App::diceware;

use strict;
use warnings;

our $VERSION = '0.01';

use File::Share ':all';
use Crypt::Rijndael;
use Crypt::URandom;
use Data::Entropy qw(with_entropy_source);
use Data::Entropy::Algorithms qw(rand_int);
use Data::Entropy::RawSource::CryptCounter;
use Data::Entropy::Source;

sub new {
    my ($class, $arg_ref) = @_;
    my $self = $arg_ref // {};
    bless $self, $class;
    $self->_init();
    return $self;
}

sub _dice {
    my ($self) = shift;
    my $dice = with_entropy_source(
        $self->{entropy},
        sub {
            rand_int(6) + 1;
        }
    );
    return $dice;
}

sub _init {
    my ($self) = shift;
    $self->{language} //= 'en';
    $self->{wordlist} = $self->_load_wordlist();
    $self->{entropy}  = $self->_build_entropy();
    return;
}

sub _load_wordlist {
    my ($self) = shift;
    die "language not supported" unless $self->{language} =~ m/^(de|en)$/xms;
    my $file = dist_file('App-diceware', "wordlist_$self->{language}.tsv");
    open(my $fh, '<:encoding(UTF-8)', $file)
        or die "Couldn't open '$file': $!";
    my $wordlist;
    while (my $line = <$fh>) {
        chomp $line;
        my ($key, $value) = split /\t/, $line, 2;
        $wordlist->{$key} = $value;
    }
    return $wordlist;
}

sub passphrase {
    my ($self, $arg_ref) = @_;
    my $length = $arg_ref->{length} // 5;
    my @passwords;
    for (my $i = 0; $i < $length; $i++) {
        my $key;
        for (0 .. 4) {
            $key .= $self->_dice();
        }
        push @passwords, $self->{wordlist}->{$key};
    }
    if ($arg_ref->{pretty}) {
        return join '-', @passwords;
    }
    return join '', @passwords;
}

sub _build_entropy {
    my $self = shift;
    return Data::Entropy::Source->new(
        Data::Entropy::RawSource::CryptCounter->new(
            Crypt::Rijndael->new(Crypt::URandom::urandom(32))
        ),
        "getc"
    );
}

1;
__END__