File Coverage

blib/lib/App/bif/work.pm

Criterion	Covered	Total	%
statement	21	51	41.1
branch	0	16	0.0
condition	0	6	0.0
subroutine	7	8	87.5
pod	1	1	100.0
total	29	82	35.3

package App::bif::work;
use strict;
use warnings;
use Bif::Mo;
use DBIx::ThinSQL qw/concat coalesce qv/;
use IO::Prompt::Tiny qw/prompt/;
use Time::Piece;

our $VERSION = '0.1.5_7';
extends 'App::bif';

sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $work = $self->current_work;
    my $dbw  = $self->dbw;

    # Nothing specified, just display the status
    if ( !exists $opts->{id} ) {
        if ($work) {
            if ( $work->{kind} eq 'topic' ) {
                printf "working %s %s %s (since %s)\n  (%s)\n", $work->{kind},
                  $work->{path},
                  $self->s2hm( time - $work->{start} ),
                  localtime( $work->{start} )->strftime('%Y-%m-%d %H:%M:%S'),
                  $work->{title};
            }
            else {
                printf "working %s %s %s (since %s)\n", $work->{kind},
                  $work->{path},
                  $self->s2hm( time - $work->{start} ),
                  localtime( $work->{start} )->strftime('%Y-%m-%d %H:%M:%S'),
                  ;
            }
            return $self->ok('Working');
        }
        print "Not currently working a node.\n";
        return $self->ok('NoWork');
    }

    my $epoch = $self->datetime2s( $opts->{at} );

    return $dbw->txn(
        sub {
            # Stop work if we were actually working
            if ($work) {
                $self->stop_work(
                    bill    => $opts->{bill},
                    stop    => $epoch,
                    comment => $opts->{comment},
                );

                printf "stopped working %s %s after %s\n", $work->{kind},
                  $work->{path},
                  $self->s2hm( $epoch - $work->{start} );
                return $self->ok('StopWork') if $opts->{id} eq '-';
            }

            if ( $opts->{id} eq '-' ) {

                print "Not currently working a node.\n";
                return $self->ok('NoWork');
            }

            # Check validity of ID
            my $info = $self->get_node( $opts->{id} );
            $opts->{id} = $info->{id};

            # Maybe complain if we are working something else
            if ($work) {
                return $self->err(
                    'WorkOther',   "working %s %s [%s] since %s",
                    $work->{kind}, $work->{node_id},
                    $work->{path}, scalar localtime( $work->{start} )
                ) unless $opts->{force};

                $opts->{comment} ||= prompt( 'Comment:', '' );
                $self->stop_work( stop => $epoch - 1 );
                printf "stopped working %s %s after %s\n", $work->{kind},
                  $work->{path},
                  $self->s2hm( $epoch - $work->{start} );
            }
            else {
                $opts->{comment} ||= prompt( 'Comment:', '' );
            }

            # Finally, start the new work

            $self->start_work(
                node_id => $info->{id},
                start   => $epoch,
                comment => $opts->{comment},
                bill    => $opts->{bill},
            );

            $work = $self->current_work;

            printf "working %s %s since %s\n", $work->{kind},
              $work->{path},
              scalar localtime( $work->{start} );

            return $self->ok('StartWork');
        }
    );

}

1;
__END__