File Coverage

blib/lib/App/bif/update/topic.pm

Criterion	Covered	Total	%
statement	12	32	37.5
branch	0	10	0.0
condition	0	3	0.0
subroutine	4	5	80.0
pod	1	1	100.0
total	17	51	33.3

package App::bif::update::topic;
use strict;
use warnings;
use Bif::Mo;

our $VERSION = '0.1.5_7';
extends 'App::bif';

sub run {
    my $self = shift;
    my $opts = $self->opts;
    my $dbw  = $self->dbw;
    my $info = $self->get_node( $self->uuid2id( $opts->{id} ), 'topic' );

    my ( $status_ids, $invalid );
    if ( $opts->{status} ) {
        my $project_id = $dbw->xval(
            select     => 'ts.project_id',
            from       => 'topics t',
            inner_join => 'topic_status ts',
            on         => 'ts.id = t.topic_status_id',
            where      => { 't.id' => $info->{id} },
        );

        ( $status_ids, $invalid ) =
          $dbw->status_ids( $project_id, 'topic', $opts->{status} );

        return $self->err( 'InvalidStatus',
            'unknown status(s): ' . join( ', ', @$invalid ) )
          if @$invalid;
    }

    if ( $opts->{reply} ) {
        my $uinfo =
          $self->get_change( $opts->{reply}, $info->{first_change_id} );
        $opts->{parent_uid} = $uinfo->{id};
    }
    else {
        $opts->{parent_uid} = $info->{first_change_id};
    }

    $dbw->txn(
        sub {
            $self->pause_work;
            my $start = time;

            $opts->{message} ||= $self->prompt_edit( opts => $self );

            $opts->{change_id} =
              $self->new_change( parent_id => $opts->{parent_uid}, );

            $dbw->xdo(
                insert_into => 'func_update_topic',
                values      => {
                    id        => $info->{id},
                    change_id => $opts->{change_id},
                    $opts->{title} ? ( title => $opts->{title} ) : (),
                    $status_ids ? ( topic_status_id => $status_ids->[0] ) : (),
                },
            );

            $self->save_new_work(
                change_id => $opts->{change_id},
                node_id   => $info->{id},
                start     => $start,
                stop      => time,
                bill      => 1,
            );

            $self->end_change(
                id               => $opts->{change_id},
                action_format    => "update $info->{tkind} %s",
                action_node_id_1 => $info->{id},
                message          => $opts->{message},
            );

            $self->resume_work;
        }
    );

    return $self->ok( 'Change' . ucfirst( $info->{tkind} ) );
}

1;
__END__